dev-util/reviewboard: add 2.5.16

Package-Manager: Portage-2.3.6, Repoman-2.3.2

2 files changed, 124 insertions, 0 deletions

diff --git a/dev-util/reviewboard/Manifest b/dev-util/reviewboard/Manifest
index bd0055ba..c9b581bb 100644
--- a/dev-util/reviewboard/Manifest
+++ b/dev-util/reviewboard/Manifest
@@ -1 +1,2 @@
 DIST ReviewBoard-2.5.15.tar.gz 13618588 SHA256 d8572337df2b0f5f32f49e62dadb65af0353e82d39983e26e40f603fc9b8d182 SHA512 1edf472597e7ac91e9a34c55c924eed436cee978d41853208758a4187e29c67d01197b56ab18b63ec673fec319442e02c359709ad5734c31c7b4d8984da3da68 WHIRLPOOL 56c2180b520c0e71832daf0cb63b8be83a727a2ff65899ebb3b816a844edc07637a6cb340a37e6eba23a26536ea879f64d772e6749fbff2ecf7bde05aa66904d
+DIST ReviewBoard-2.5.16.tar.gz 13622360 SHA256 c424c5e2a9305c2f95d87198193d0ee26e3486cb1ca75fdbe312e47f4da039d2 SHA512 d7c1368fc1b11a898a086a4fdf0cc30aab92a78e3617f04e686c5c6363ccd487e818a8c16525c1b872e0120d4f939972b95a4ec95f95b857b19b846b0dda237b WHIRLPOOL db5e65a98e1dfab7e3bd2fd5d52e68ce73d25be1f1767fa57fd53c3c829ad76dc63c6c0f9a78862434511f4109a5e92c85c4bb9a2a0726cd36ee06bb490af2fb
diff --git a/dev-util/reviewboard/reviewboard-2.5.16.ebuild b/dev-util/reviewboard/reviewboard-2.5.16.ebuild
new file mode 100644
index 00000000..27fcb9e1
--- /dev/null
+++ b/dev-util/reviewboard/reviewboard-2.5.16.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+MY_PN="ReviewBoard"
+DESCRIPTION="A web-based code review tool that offers developers a way to handle code reviews"
+HOMEPAGE="https://www.reviewboard.org/"
+SRC_URI="https://downloads.reviewboard.org/releases/${MY_PN}/2.5/${MY_PN}-${PV}.tar.gz"
+KEYWORDS="~amd64"
+IUSE="codebase doc manual ldap rnotes test"
+
+LICENSE="MIT"
+SLOT="0"
+S=${WORKDIR}/${MY_PN}-${PV}
+
+RDEPEND=">=dev-python/django-1.6.11.1[${PYTHON_USEDEP},sqlite]
+	<dev-python/django-1.7[${PYTHON_USEDEP},sqlite]
+	>=dev-python/django-evolution-0.7.7[${PYTHON_USEDEP}]
+	<dev-python/django-evolution-0.8[${PYTHON_USEDEP}]
+	>=dev-python/django-haystack-2.3.1[${PYTHON_USEDEP}]
+	<dev-python/django-haystack-2.5[${PYTHON_USEDEP}]
+	dev-python/django-multiselectfield[${PYTHON_USEDEP}]
+	>=dev-python/Djblets-0.9.9[${PYTHON_USEDEP}]
+	<dev-python/Djblets-0.10[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-1.8.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.1[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
+	>=dev-python/markdown-2.6.0[${PYTHON_USEDEP}]
+	<dev-python/markdown-2.7[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-1.12[${PYTHON_USEDEP}]
+	>=dev-python/mimeparse-0.1.3[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
+	dev-python/python-memcached[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2015.2[${PYTHON_USEDEP}]
+	dev-python/recaptcha-client[${PYTHON_USEDEP}]
+	>=dev-python/whoosh-2.6[${PYTHON_USEDEP}]
+	ldap? ( >=dev-python/python-ldap-2.4.21[${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+REQUIRED_USE="doc? ( || ( codebase manual rnotes ) )"
+# Tests mostly access the inet and when run mostly fail
+RESTRICT=test
+
+python_prepare_all() {
+	# Running uglify is a problem right now, so skip this step. Rather
+	# have newer versions than compacted javascript.
+	sed -e "s/'pipeline.compressors.uglifyjs.UglifyJSCompressor'/None/" -i reviewboard/settings.py || die
+
+	# Use newer markdown version still available
+	sed -i -e '/markdown/ s/2.4/2.6/g' reviewboard/dependencies.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# See https://code.google.com/p/reviewboard/issues/ #3009
+	# until build of manual can find and use ROOT_URLCONF, only possible build path for manual
+	# requires sacrificing the resources section, all of which call on ROOT_URLCONF
+	local msg="Generating docs for"
+	if use doc; then
+		if use manual; then
+			rm -rf docs/manual/webapi//2.0/resources/ || die
+			einfo;einfo "$msg manual"
+			DJANGO_SETTINGS_MODULE="django.conf" emake -C docs/manual html
+		fi
+
+		if use codebase; then
+			pushd docs/codebase &> /dev/null
+			ln -sf ../../contrib/internal/conf/settings_local.py .
+			popd &> /dev/null
+			einfo;einfo "$msg codebase"
+			emake -C docs/codebase html
+		fi
+
+		if use rnotes; then
+			einfo;einfo "$msg release notes"
+			emake -C docs/releasenotes html
+		fi
+	fi
+}
+
+python_test() {
+	pushd ${PN} > /dev/null
+	ln -sf contrib/internal/conf/settings_local.py .
+	"${PYTHON}" manage.py test || die
+}
+
+python_install_all() {
+	if use doc; then
+		if use manual; then
+			insinto /usr/share/doc/${PF}/manual
+			doins -r docs/manual/_build/html/
+		fi
+		if use codebase; then
+			insinto /usr/share/doc/${PF}/codebase
+			doins -r docs/codebase/_build/html/
+		fi
+		if use rnotes; then
+			insinto /usr/share/doc/${PF}/release_notes
+			doins -r docs/releasenotes/_build/html/
+		fi
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	elog "You must install any VCS tool you wish ${PN} to support."
+	elog "dev-util/cvs, dev-vcs/git, dev-vcs/mercurial or dev-util/subversion."
+	elog
+	elog "Install dev-python/mysql-python for mysql support."
+	elog "Install dev-python/psycopg for postgres support."
+	elog
+	elog "For speed and responsiveness, consider installing net-misc/memcached"
+	elog "and dev-python/python-memcached"
+}