media-tv/kodi: use a stacksize of 1M for musl users

Package-Manager: Portage-3.0.18, Repoman-3.0.2
Signed-off-by: Jory Pratt <anarchy@gentoo.org>

3 files changed, 4 insertions, 366 deletions

diff --git a/media-tv/kodi/Manifest b/media-tv/kodi/Manifest
index cdf47612..f63a7244 100644
--- a/media-tv/kodi/Manifest
+++ b/media-tv/kodi/Manifest
@@ -1,6 +1,4 @@
-DIST ffmpeg-kodi-4.3.1-Matrix-Beta1.tar.gz 13477440 BLAKE2B 49415f76fd2a888b0efadb19597bd89db65c3d9e1224ab529ff0d73ab5734a23982b4d4905ddeb105ce59a816c4642cdb9f5568b0c39c29f5fb9431f9623d4ec SHA512 ce43390e816dabeed4ca231f5f7adade6c721c38e17996a57810fb6025ea49b812133c2a6e29aac7c674d4e4af3a21dbd7e605d85fb966935a01bda983b884ac
 DIST ffmpeg-kodi-4.3.2-Matrix-19.1.tar.gz 13490949 BLAKE2B 90007f2c4bac0e0a52b419d9333cf75b00e291f1ea7447cbdc579ee2f860de7c436c924253600f3fbd6e3faaabe97aaf46db083a5bbd2f5f03badcca5d643e89 SHA512 d3719253d674b16638b873545583b82fba3176803c81ba8bcb37e90456dd956f1c2ee8996493840cff2d61c6399f06ed0524a759f46e4ce174bce23e9c6eda4a
-DIST kodi-19.0.tar.gz 52311355 BLAKE2B 543936b8fb607d1d629a8f2abd9cd0cb3bf6114aa93647c7e8ccee2f99ff1f84a2740bb57f0cbf675b3efa5914e98c57effb28ecd8e9df83a39d67ee708280a2 SHA512 d6c9fe7414b64d33d919d6c3de1ddb4800e36b786a460d2d2f5c1e5346cd4819487e54f212c37778103d44dd051f7df6c74e0a98a0b21d1e4dc9bedaa8570422
 DIST kodi-19.1.tar.gz 52323919 BLAKE2B 6aa82632d2d70e5f84340c572b586e903e7dbc50c4f99fc5118761d495bd13dcbbcd70462e6288147dd4a305952d1e07f08daf45bbc402b59e3ef785391e1fe7 SHA512 725cbc270259ef5d3b79f9bc271b789dc8ef6616a6d4038e0cd449755ca4ed25198ad6e854b304aedc1fb911ecb98a0aad1b3e469857f8aed54fc4634193eb75
 DIST libdvdcss-1.4.2-Leia-Beta-5.tar.gz 101068 BLAKE2B 283aa2cec0a2200d3569bc280cb9659e9224a6b3a77db8a35b269cd8caf1337ac9d8b92b806df66f63ef7458a46bd6261f0b8b14678b10e26644a79dcbeea5da SHA512 5185dbdbeb1bd13ea9d8723f1f4ab599d6f3102f5ba1096cd085aa1cda252c045f327c719227bba8e1b742352ade5e335106c8d0c1637a5a6b93ce661620dd7e
 DIST libdvdnav-6.0.0-Leia-Alpha-3.tar.gz 137942 BLAKE2B 7573434a0ae8e8ccabf48173f81fcde29074eb138e119a2ae9156cde3c3d8bfd716f5d0e605b97f2dcac21f570781137c8533c5ae306b51e3905822fda318355 SHA512 11c93eaacd156f8fd7dec7c43d366438b201f31ad55b2870463a9e286912b6ada08882319a021fb7992190f87b909a49f2b83e0321cc17aedc29f7fe5898fa72
diff --git a/media-tv/kodi/kodi-19.0.ebuild b/media-tv/kodi/kodi-19.0.ebuild
deleted file mode 100644
index 44952aa6..00000000
--- a/media-tv/kodi/kodi-19.0.ebuild
+++ /dev/null
@@ -1,363 +0,0 @@
-	# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_REQ_USE="sqlite,ssl"
-LIBDVDCSS_VERSION="1.4.2-Leia-Beta-5"
-LIBDVDREAD_VERSION="6.0.0-Leia-Alpha-3"
-LIBDVDNAV_VERSION="6.0.0-Leia-Alpha-3"
-FFMPEG_VERSION="4.3.1"
-CODENAME="Matrix"
-FFMPEG_KODI_VERSION="Beta1"
-PYTHON_COMPAT=( python3_{6,7,8,9} )
-SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_VERSION}.tar.gz -> libdvdcss-${LIBDVDCSS_VERSION}.tar.gz
-	https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_VERSION}.tar.gz -> libdvdread-${LIBDVDREAD_VERSION}.tar.gz
-	https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_VERSION}.tar.gz -> libdvdnav-${LIBDVDNAV_VERSION}.tar.gz
-	!system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )"
-if [[ ${PV} == *9999 ]] ; then
-	EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
-	EGIT_BRANCH="Matrix"
-	inherit git-r3
-else
-	MY_PV=${PV/_p/_r}
-	MY_PV=${MY_PV/_alpha/a}
-	MY_PV=${MY_PV/_beta/b}
-	MY_PV=${MY_PV/_rc/RC}
-	MY_P="${PN}-${MY_PV}"
-	SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz"
-	KEYWORDS="~amd64 ~arm arm64 ~x86"
-	S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
-fi
-
-inherit autotools cmake desktop linux-info pax-utils python-single-r1 xdg
-
-DESCRIPTION="A free and open source media-player and entertainment hub"
-HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
-
-LICENSE="GPL-2+"
-SLOT="0"
-# use flag is called libusb so that it doesn't fool people in thinking that
-# it is _required_ for USB support. Otherwise they'll disable udev and
-# that's going to be worse.
-IUSE="airplay alsa bluetooth bluray caps cec +css dav1d dbus eventclients gbm gles lcms libusb lirc mariadb mysql nfs +optical power-control pulseaudio raspberry-pi samba +system-ffmpeg test udf udev udisks upnp upower vaapi vdpau wayland webserver +X +xslt zeroconf"
-IUSE="${IUSE} cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 cpu_flags_x86_avx cpu_flags_x86_avx2 cpu_flags_arm_neon"
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	|| ( gbm wayland X )
-	?? ( mariadb mysql )
-	bluray? ( udf )
-	udev? ( !libusb )
-	udisks? ( dbus )
-	upower? ( dbus )
-	power-control? ( dbus )
-	vdpau? (
-		X
-		!gles
-		!gbm
-	)
-	zeroconf? ( dbus )
-"
-RESTRICT="!test? ( test )"
-
-COMMON_DEPEND="
-	>=dev-libs/lzo-2.04
-	>=dev-libs/flatbuffers-1.11.0
-	>=media-libs/libjpeg-turbo-2.0.4:=
-	>=media-libs/libpng-1.6.26:0=
-"
-COMMON_TARGET_DEPEND="${PYTHON_DEPS}
-	airplay? (
-		>=app-pda/libplist-2.0.0
-		net-libs/shairplay
-	)
-	alsa? ( >=media-libs/alsa-lib-1.1.4.1 )
-	bluetooth? ( net-wireless/bluez )
-	bluray? ( >=media-libs/libbluray-1.1.2 )
-	caps? ( sys-libs/libcap )
-	dbus? ( sys-apps/dbus )
-	dev-db/sqlite
-	dev-libs/crossguid
-	>=dev-libs/fribidi-1.0.5
-	cec? ( >=dev-libs/libcec-4.0[raspberry-pi?] )
-	dev-libs/libpcre[cxx]
-	>=dev-libs/spdlog-1.5.0:=
-	dev-libs/tinyxml[stl]
-	$(python_gen_cond_dep '
-		dev-python/pillow[${PYTHON_MULTI_USEDEP}]
-		dev-python/pycryptodome[${PYTHON_MULTI_USEDEP}]
-	')
-	>=dev-libs/libcdio-2.1.0[cxx]
-	>=dev-libs/libfmt-6.1.2
-	dev-libs/libfstrcmp
-	gbm? (
-		>=dev-libs/libinput-1.10.5
-		media-libs/mesa[gbm]
-		x11-libs/libxkbcommon
-	)
-	gles? (
-		!raspberry-pi? ( media-libs/mesa[gles2] )
-	)
-	lcms? ( media-libs/lcms:2 )
-	libusb? ( virtual/libusb:1 )
-	virtual/ttf-fonts
-	media-fonts/roboto
-	>=media-libs/freetype-2.10.1
-	>=media-libs/libass-0.13.4
-	!raspberry-pi? ( media-libs/mesa[egl] )
-	>=media-libs/taglib-1.11.1
-	system-ffmpeg? (
-		>=media-video/ffmpeg-${FFMPEG_VERSION}:=[dav1d?,encode,postproc]
-		media-video/ffmpeg[openssl]
-	)
-	!system-ffmpeg? (
-		app-arch/bzip2
-		dav1d? ( media-libs/dav1d )
-	)
-	mysql? ( dev-db/mysql-connector-c:= )
-	mariadb? ( dev-db/mariadb-connector-c:= )
-	>=net-misc/curl-7.68.0[http2]
-	nfs? ( >=net-fs/libnfs-2.0.0:= )
-	!gles? ( media-libs/glu )
-	>=dev-libs/openssl-1.0.2l:0=
-	raspberry-pi? (
-		|| ( media-libs/raspberrypi-userland media-libs/raspberrypi-userland-bin media-libs/mesa[egl,gles2,video_cards_vc4] )
-	)
-	pulseaudio? ( media-sound/pulseaudio )
-	samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
-	>=sys-libs/zlib-1.2.11
-	udf? ( >=dev-libs/libudfread-1.0.0 )
-	udev? ( virtual/udev )
-	vaapi? (
-		x11-libs/libva:=
-		!gles? ( x11-libs/libva[opengl] )
-		system-ffmpeg? ( media-video/ffmpeg[vaapi] )
-		vdpau? ( x11-libs/libva[vdpau] )
-		wayland? ( x11-libs/libva[wayland] )
-		X? ( x11-libs/libva[X] )
-	)
-	virtual/libiconv
-	vdpau? (
-		|| ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
-		system-ffmpeg? ( media-video/ffmpeg[vdpau] )
-	)
-	wayland? (
-		>=dev-cpp/waylandpp-0.2.3:=
-		media-libs/mesa[wayland]
-		>=dev-libs/wayland-protocols-1.7
-		>=x11-libs/libxkbcommon-0.4.1
-	)
-	webserver? ( >=net-libs/libmicrohttpd-0.9.55[messages(+)] )
-	X? (
-		media-libs/mesa[X]
-		!gles? ( media-libs/libglvnd[X] )
-		x11-libs/libX11
-		x11-libs/libXrandr
-		x11-libs/libXrender
-		system-ffmpeg? ( media-video/ffmpeg[X] )
-	)
-	x11-libs/libdrm
-	xslt? (
-		dev-libs/libxslt
-		>=dev-libs/libxml2-2.9.4
-	)
-	zeroconf? ( net-dns/avahi[dbus] )
-"
-RDEPEND="${COMMON_DEPEND} ${COMMON_TARGET_DEPEND}
-	lirc? ( app-misc/lirc )
-	power-control? ( || ( sys-apps/systemd sys-auth/elogind ) )
-	udisks? ( sys-fs/udisks:2 )
-	upower? ( sys-power/upower )
-"
-DEPEND="${COMMON_DEPEND} ${COMMON_TARGET_DEPEND}
-	dev-libs/rapidjson
-	test? ( >=dev-cpp/gtest-1.10.0 )
-"
-BDEPEND="${COMMON_DEPEND}
-	dev-lang/swig
-	dev-util/cmake
-	media-libs/giflib
-	>=dev-libs/flatbuffers-1.11.0
-	>=media-libs/libjpeg-turbo-2.0.4:=
-	>=media-libs/libpng-1.6.26:0=
-	virtual/pkgconfig
-	virtual/jre
-"
-
-CONFIG_CHECK="~IP_MULTICAST"
-ERROR_IP_MULTICAST="
-In some cases Kodi needs to access multicast addresses.
-Please consider enabling IP_MULTICAST under Networking options.
-"
-
-PATCHES=(
-	"${FILESDIR}/musl/19.0/0001-add-missing-stdint.h.patch"
-	"${FILESDIR}/musl/19.0/0002-fix-fileemu.patch"
-	"${FILESDIR}/musl/19.0/0003-Use-stdint.h-defined-types-uint8_t-uint16_t-uint32_t.patch"
-	"${FILESDIR}/musl/19.0/0004-Fix-ldt-for-musl.patch"
-	"${FILESDIR}/musl/19.0/0005-Fix-fortify-sources.patch"
-)
-
-pkg_setup() {
-	check_extra_config
-	python-single-r1_pkg_setup
-}
-
-src_unpack() {
-	if [[ ${PV} == *9999 ]] ; then
-		git-r3_src_unpack
-	else
-		default
-	fi
-}
-
-src_prepare() {
-	cmake_src_prepare
-
-	# avoid long delays when powerkit isn't running #348580
-	sed -i \
-		-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
-		xbmc/platform/linux/*.cpp || die
-
-	# Prepare tools and libs witch are configured with autotools during compile time
-	AUTOTOOLS_DIRS=(
-		"${S}"/tools/depends/native/TexturePacker/src
-		"${S}"/tools/depends/native/JsonSchemaBuilder/src
-	)
-
-	local d
-	for d in "${AUTOTOOLS_DIRS[@]}" ; do
-		pushd ${d} >/dev/null || die
-		AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
-		popd >/dev/null || die
-	done
-	elibtoolize
-
-	# Prevent autoreconf rerun
-	sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
-		"${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
-		"${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
-		|| die
-}
-
-src_configure() {
-	local platform=()
-	use gbm && platform+=( gbm )
-	use wayland && platform+=( wayland )
-	use X && platform+=( x11 )
-	local core_platform_name="${platform[@]}"
-	local mycmakeargs=(
-		-DENABLE_SSE=$(usex cpu_flags_x86_sse)
-		-DENABLE_SSE2=$(usex cpu_flags_x86_sse2)
-		-DENABLE_SSE3=$(usex cpu_flags_x86_sse3)
-		-DENABLE_SSE4_1=$(usex cpu_flags_x86_sse4_1)
-		-DENABLE_SSE4_2=$(usex cpu_flags_x86_sse4_2)
-		-DENABLE_AVX=$(usex cpu_flags_x86_avx)
-		-DENABLE_AVX2=$(usex cpu_flags_x86_avx2)
-		-DENABLE_NEON=$(usex cpu_flags_arm_neon)
-		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
-		-DVERBOSE=ON
-		-DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
-		-DENABLE_ALSA=$(usex alsa)
-		-DENABLE_AIRTUNES=$(usex airplay)
-		-DENABLE_AVAHI=$(usex zeroconf)
-		-DENABLE_BLUETOOTH=$(usex bluetooth)
-		-DENABLE_BLURAY=$(usex bluray)
-		-DENABLE_CCACHE=OFF
-		-DENABLE_CLANGFORMAT=OFF
-		-DENABLE_CLANGTIDY=OFF
-		-DENABLE_CPPCHECK=OFF
-		-DENABLE_ISO9660PP=$(usex optical)
-		-DENABLE_CEC=$(usex cec)
-		-DENABLE_DBUS=$(usex dbus)
-		-DENABLE_DVDCSS=$(usex css)
-		-DENABLE_EVENTCLIENTS=ON # alway enable to have 'kodi-send' and filter extra staff in 'src_install()'
-		-DENABLE_INTERNAL_CROSSGUID=OFF
-		-DENABLE_INTERNAL_RapidJSON=OFF
-		-DENABLE_INTERNAL_FMT=OFF
-		-DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
-		-DENABLE_INTERNAL_FSTRCMP=OFF
-		-DENABLE_INTERNAL_FLATBUFFERS=OFF
-		-DENABLE_INTERNAL_DAV1D=OFF
-		-DENABLE_INTERNAL_GTEST=OFF
-		-DENABLE_INTERNAL_UDFREAD=OFF
-		-DENABLE_INTERNAL_SPDLOG=OFF
-		-DENABLE_CAP=$(usex caps)
-		-DENABLE_LCMS2=$(usex lcms)
-		-DENABLE_LIRCCLIENT=$(usex lirc)
-		-DENABLE_MARIADBCLIENT=$(usex mariadb)
-		-DENABLE_MDNS=OFF # used only on Android
-		-DENABLE_MICROHTTPD=$(usex webserver)
-		-DENABLE_MYSQLCLIENT=$(usex mysql)
-		-DENABLE_NFS=$(usex nfs)
-		-DENABLE_OPENGLES=$(usex gles)
-		-DENABLE_OPENGL=$(usex !gles)
-		-DENABLE_OPTICAL=$(usex optical)
-		-DENABLE_PLIST=$(usex airplay)
-		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
-		-DENABLE_SMBCLIENT=$(usex samba)
-		-DENABLE_SNDIO=OFF
-		-DENABLE_TESTING=$(usex test)
-		-DENABLE_UDEV=$(usex udev)
-		-DENABLE_UDFREAD=$(usex udf)
-		-DENABLE_UPNP=$(usex upnp)
-		-DENABLE_VAAPI=$(usex vaapi)
-		-DENABLE_VDPAU=$(usex vdpau)
-		-DENABLE_XSLT=$(usex xslt)
-		-Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_VERSION}.tar.gz"
-		-Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_VERSION}.tar.gz"
-		-Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_VERSION}.tar.gz"
-		-DPYTHON_INCLUDE_DIR="$(python_get_includedir)"
-		-DPYTHON_LIBRARY="$(python_get_library_path)"
-		-DAPP_RENDER_SYSTEM="$(usex gles gles gl)"
-		-DCORE_PLATFORM_NAME="${core_platform_name}"
-	)
-
-	use !udev && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
-
-	use X && use !gles && mycmakeargs+=( -DENABLE_GLX=ON )
-
-	if use system-ffmpeg; then
-		mycmakeargs+=( -DWITH_FFMPEG="yes" )
-	else
-		mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
-	fi
-
-	if ! echo "${CFLAGS}" | grep -Fwqe '-DNDEBUG' - && ! echo "${CFLAGS}" | grep -Fwqe '-D_DEBUG' - ; then
-		CFLAGS+=' -DNDEBUG' # Kodi requires one of the 'NDEBUG' or '_DEBUG' defines
-		CXXFLAGS+=' -DNDEBUG'
-	fi
-
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile all
-}
-
-src_test() {
-	# see https://github.com/xbmc/xbmc/issues/17860#issuecomment-630120213
-	KODI_HOME="${BUILD_DIR}" cmake_build check
-}
-
-src_install() {
-	cmake_src_install
-
-	pax-mark Em "${ED}"/usr/$(get_libdir)/${PN}/${PN}.bin
-
-	newicon media/icon48x48.png kodi.png
-
-	rm "${ED}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
-	dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
-		usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
-
-	if use !eventclients ; then
-		rm -f "${ED}"/usr/bin/kodi-ps3remote || die
-		rm -f "${D}"$(python_get_sitedir)/kodi/ps3_remote.py || die
-		rm -rf "${D}"$(python_get_sitedir)/kodi/ps3 || die
-		rm -rf "${D}"$(python_get_sitedir)/kodi/bt || die
-		rm -rf "${ED}"/usr/share/doc/${PF}/kodi-eventclients-dev || die
-	fi
-
-	python_optimize "${D}$(python_get_sitedir)"
-}
diff --git a/media-tv/kodi/kodi-19.1.ebuild b/media-tv/kodi/kodi-19.1.ebuild
index 870b01bd..9cbf604a 100644
--- a/media-tv/kodi/kodi-19.1.ebuild
+++ b/media-tv/kodi/kodi-19.1.ebuild
@@ -30,7 +30,7 @@ else
 	S=${WORKDIR}/xbmc-${MY_PV}
 fi
 
-inherit autotools cmake desktop linux-info pax-utils python-single-r1 xdg
+inherit autotools cmake desktop flag-o-matic linux-info pax-utils python-single-r1 xdg
 
 DESCRIPTION="A free and open source media-player and entertainment hub"
 HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
@@ -238,6 +238,9 @@ src_prepare() {
 		"${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
 		"${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
 		|| die
+
+	# Required to prevent addons from crashing
+	use elibc_musl && append-ldflags -Wl,-z,stack-size=1048576
 }
 
 src_configure() {