x11-misc/sddm: Sync Gentoo ebuild repo changes, drop broken patches

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 51 insertions, 37 deletions

diff --git a/x11-misc/sddm/sddm-9999.ebuild b/x11-misc/sddm/sddm-9999.ebuild
index f9b3950f..fd6d2f6b 100644
--- a/x11-misc/sddm/sddm-9999.ebuild
+++ b/x11-misc/sddm/sddm-9999.ebuild
@@ -1,72 +1,71 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 if [[ ${PV} == *9999* ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
 else
 	SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
 fi
 
-PLOCALES="ar bn ca cs da de es et fi fr hi_IN hu ie is it ja kk ko lt lv nb nl nn pl pt_BR pt_PT ro ru sk sr sr@ijekavian sr@ijekavianlatin sr@latin sv tr uk zh_CN zh_TW"
-inherit cmake plocale systemd user
+inherit cmake linux-info systemd tmpfiles
 
 DESCRIPTION="Simple Desktop Display Manager"
 HOMEPAGE="https://github.com/sddm/sddm"
 
 LICENSE="GPL-2+ MIT CC-BY-3.0 CC-BY-SA-3.0 public-domain"
 SLOT="0"
-IUSE="elogind +pam systemd test"
+IUSE="+elogind +pam systemd test"
 
 REQUIRED_USE="?? ( elogind systemd )"
-
 RESTRICT="!test? ( test )"
 
-BDEPEND="
-	dev-python/docutils
-	>=dev-qt/linguist-tools-5.9.4:5
-	kde-frameworks/extra-cmake-modules:5
-	virtual/pkgconfig
-"
-RDEPEND="
-	>=dev-qt/qtcore-5.9.4:5
-	>=dev-qt/qtdbus-5.9.4:5
-	>=dev-qt/qtdeclarative-5.9.4:5
-	>=dev-qt/qtgui-5.9.4:5
-	>=dev-qt/qtnetwork-5.9.4:5
-	>=x11-base/xorg-server-1.15.1
+COMMON_DEPEND="
+	acct-group/sddm
+	acct-user/sddm
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	x11-base/xorg-server
 	x11-libs/libxcb[xkb]
 	elogind? ( sys-auth/elogind )
 	pam? ( sys-libs/pam )
+	!pam? ( virtual/libcrypt:= )
 	systemd? ( sys-apps/systemd:= )
 	!systemd? ( sys-power/upower )
 "
-DEPEND="${RDEPEND}
-	test? ( >=dev-qt/qttest-5.9.4:5 )
+DEPEND="${COMMON_DEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!systemd? ( gui-libs/display-manager-init )
+"
+BDEPEND="
+	dev-python/docutils
+	dev-qt/linguist-tools:5
+	kde-frameworks/extra-cmake-modules:5
+	virtual/pkgconfig
 "
 
 PATCHES=(
-	# Pending upstream
-	# fix for groups: https://github.com/sddm/sddm/issues/1159
-	"${FILESDIR}"/${PN}-0.18.1-revert-honor-PAM-supplemental-groups.patch
-	"${FILESDIR}"/${PN}-0.18.1-honor-PAM-supplemental-groups-v2.patch
 	# Downstream patches
-	"${FILESDIR}"/${PN}-0.18.1-respect-user-flags.patch # bug 563108
-	"${FILESDIR}"/${PN}-0.19.0-Xsession.patch # bug 611210
+	"${FILESDIR}/${PN}-0.18.1-respect-user-flags.patch" # bug 563108
+	"${FILESDIR}/${PN}-0.19.0-Xsession.patch" # bug 611210
 )
 
+pkg_setup() {
+	local CONFIG_CHECK="~DRM"
+	use kernel_linux && linux-info_pkg_setup
+}
+
 src_prepare() {
 	cmake_src_prepare
 
-	disable_locale() {
-		sed -e "/${1}\.ts/d" -i data/translations/CMakeLists.txt || die
-	}
-	plocale_find_changes "data/translations" "" ".ts"
-	plocale_for_each_disabled_locale disable_locale
-
 	if ! use test; then
 		sed -e "/^find_package/s/ Test//" -i CMakeLists.txt || die
 		cmake_comment_add_subdirectory test
@@ -87,6 +86,8 @@ src_configure() {
 src_install() {
 	cmake_src_install
 
+	newtmpfiles "${FILESDIR}/${PN}.tmpfiles" "${PN}.conf"
+
 	# Create a default.conf as upstream dropped /etc/sddm.conf w/o replacement
 	local confd="/usr/lib/sddm/sddm.conf.d"
 	dodir ${confd}
@@ -100,12 +101,25 @@ src_install() {
 }
 
 pkg_postinst() {
+	tmpfiles_process "${PN}.conf"
+
 	elog "Starting with 0.18.0, SDDM no longer installs /etc/sddm.conf"
 	elog "Use it to override specific options. SDDM defaults are now"
 	elog "found in: /usr/lib/sddm/sddm.conf.d/00default.conf"
-
-	enewgroup ${PN}
-	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN},video
+	elog
+	elog "NOTE: If SDDM startup appears to hang then entropy pool is too low."
+	elog "This can be fixed by configuring one of the following:"
+	elog "  - Enable CONFIG_RANDOM_TRUST_CPU in linux kernel"
+	elog "  - # emerge sys-apps/haveged && rc-update add haveged boot"
+	elog "  - # emerge sys-apps/rng-tools && rc-update add rngd boot"
+	elog
+	elog "For more information on how to configure SDDM, please visit the wiki:"
+	elog "  https://wiki.gentoo.org/wiki/SDDM"
+	if has_version x11-drivers/nvidia-drivers; then
+		elog
+		elog "  Nvidia GPU owners in particular should pay attention"
+		elog "  to the troubleshooting section."
+	fi
 
 	systemd_reenable sddm.service
 }