blob: 1d6cd43040d0339bfabf7825719265a3980445b9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI=5
QT5_MODULE="qtbase"
inherit qt5-build
DESCRIPTION="The GUI module and platform plugins for the Qt5 framework"
if [[ ${QT5_BUILD_TYPE} == release ]]; then
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~x86"
fi
# TODO: directfb, linuxfb, offscreen (auto-depends on X11)
IUSE="accessibility egl eglfs evdev +gif gles2 gtkstyle +harfbuzz ibus jpeg kms +png udev +xcb"
REQUIRED_USE="
egl? ( evdev )
eglfs? ( egl )
kms? ( egl gles2 )
"
RDEPEND="
dev-libs/glib:2
~dev-qt/qtcore-${PV}[debug=]
media-libs/fontconfig
>=media-libs/freetype-2.5.5:2
>=sys-libs/zlib-1.2.5
virtual/opengl
egl? ( media-libs/mesa[egl] )
evdev? ( sys-libs/mtdev )
gtkstyle? (
x11-libs/gtk+:2
x11-libs/pango
!!x11-libs/cairo[qt4]
)
gles2? ( media-libs/mesa[gles2] )
harfbuzz? ( >=media-libs/harfbuzz-0.9.40:= )
ibus? ( ~dev-qt/qtdbus-${PV}[debug=] )
jpeg? ( virtual/jpeg:0 )
kms? (
media-libs/mesa[gbm]
virtual/libudev:=
x11-libs/libdrm
)
png? ( media-libs/libpng:0= )
udev? ( virtual/libudev:= )
xcb? (
x11-libs/libICE
x11-libs/libSM
>=x11-libs/libX11-1.5
>=x11-libs/libXi-1.6
x11-libs/libXrender
>=x11-libs/libxcb-1.10:=[xkb]
>=x11-libs/libxkbcommon-0.4.1[X]
x11-libs/xcb-util-image
x11-libs/xcb-util-keysyms
x11-libs/xcb-util-renderutil
x11-libs/xcb-util-wm
accessibility? ( ~dev-qt/qtdbus-${PV}[debug=] )
)
"
DEPEND="${RDEPEND}
evdev? ( sys-kernel/linux-headers )
test? ( ~dev-qt/qtnetwork-${PV}[debug=] )
"
PDEPEND="
ibus? ( app-i18n/ibus )
"
QT5_TARGET_SUBDIRS=(
src/gui
src/openglextensions
src/platformheaders
src/platformsupport
src/plugins/generic
src/plugins/imageformats
src/plugins/platforms
)
QT5_GENTOO_CONFIG=(
accessibility:accessibility-atspi-bridge
egl
eglfs
evdev
evdev:mtdev:
:fontconfig
:system-freetype:FREETYPE
!:no-freetype:
!gif:no-gif:
gles2::OPENGL_ES
gles2:opengles2:OPENGL_ES_2
gtkstyle:gtkstyle:
gtkstyle:gtk2:STYLE_GTK
!:no-gui:
harfbuzz:system-harfbuzz:HARFBUZZ
!harfbuzz:no-harfbuzz:
jpeg:system-jpeg:IMAGEFORMAT_JPEG
!jpeg:no-jpeg:
kms:kms:
:opengl
png:png:
png:system-png:IMAGEFORMAT_PNG
!png:no-png:
udev:libudev:
xcb:xcb:
xcb:xcb-glx:
xcb:xcb-plugin:
xcb:xcb-render:
xcb:xcb-sm:
xcb:xcb-xlib:
xcb:xinput2:
xcb::XKB
)
pkg_setup() {
use gtkstyle && QT5_TARGET_SUBDIRS+=(src/plugins/platformthemes/gtk2)
use ibus && QT5_TARGET_SUBDIRS+=(src/plugins/platforminputcontexts/ibus)
use xcb && QT5_TARGET_SUBDIRS+=(src/plugins/platforminputcontexts/compose)
# egl_x11 is activated when both egl and xcb are enabled
use egl && QT5_GENTOO_CONFIG+=(xcb:egl_x11) || QT5_GENTOO_CONFIG+=(egl:egl_x11)
}
src_configure() {
local myconf=(
$(use accessibility && usex xcb -dbus-linked '')
$(usex ibus -dbus-linked '')
$(qt_use egl)
$(qt_use eglfs)
$(qt_use evdev)
$(qt_use evdev mtdev)
-fontconfig
-system-freetype
$(usex gif '' -no-gif)
$(qt_use gtkstyle)
$(qt_use harfbuzz harfbuzz system)
$(qt_use jpeg libjpeg system)
$(qt_use kms)
-opengl $(usex gles2 es2 desktop)
$(qt_use png libpng system)
$(qt_use udev libudev)
$(qt_use xcb xcb system)
$(qt_use xcb xkbcommon system)
$(use xcb && echo -xcb-xlib -xinput2 -xkb -xrender)
)
qt5-build_src_configure
}
|