dev-util/pkgconf: bump to 1.4.2

Package-Manager: Portage-2.3.24, Repoman-2.3.6_p81

1 files changed, 72 insertions, 0 deletions

diff --git a/dev-util/pkgconf/pkgconf-1.4.2.ebuild b/dev-util/pkgconf/pkgconf-1.4.2.ebuild
new file mode 100644
index 000000000000..e2b768e8e572
--- /dev/null
+++ b/dev-util/pkgconf/pkgconf-1.4.2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://distfiles.dereferenced.org/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+inherit multilib-minimal
+
+DESCRIPTION="pkg-config compatible replacement with no dependencies other than ANSI C89"
+HOMEPAGE="https://github.com/pkgconf/pkgconf"
+
+LICENSE="BSD-1"
+SLOT="0/3"
+IUSE="+pkg-config test"
+
+# tests require 'kyua'
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	test? (
+		dev-libs/atf
+		dev-util/kyua
+	)
+"
+RDEPEND="
+	pkg-config? (
+		!dev-util/pkgconfig
+		!dev-util/pkg-config-lite
+		!dev-util/pkgconfig-openbsd[pkg-config]
+	)
+"
+
+MULTILIB_CHOST_TOOLS=(
+	/usr/bin/pkgconf
+)
+
+src_prepare() {
+	default
+
+	[[ ${PV} == "9999" ]] && eautoreconf
+	if use pkg-config; then
+		MULTILIB_CHOST_TOOLS+=(
+			/usr/bin/pkg-config
+		)
+	fi
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} econf
+}
+
+multilib_src_install() {
+	default
+
+	if use pkg-config; then
+		dosym pkgconf /usr/bin/pkg-config
+	else
+		rm "${ED%/}"/usr/share/aclocal/pkg.m4 || die
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}