net-analyzer/pmacct: add 1.7.7, rename live

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 152 insertions, 31 deletions

diff --git a/net-analyzer/pmacct/Manifest b/net-analyzer/pmacct/Manifest
index f55cc8513620..8ca96495e5e3 100644
--- a/net-analyzer/pmacct/Manifest
+++ b/net-analyzer/pmacct/Manifest
@@ -1 +1,2 @@
 DIST pmacct-1.7.6.tar.gz 2126837 BLAKE2B df04822e88f9409d335457031fb26ce4ae8b5da13cf2f55f8d6c78eb50dade62ef763d389ac81a509d9351e12844446ac73171e9966a5aeeecc0e5fb10219c73 SHA512 b370d20f8b8d49b9114db3ab74c66cd16962dee5e7c3642fab0b2787c4ea924a249ff4d8d770c0ccc8ca81366b9a5e557dcfb7cdddf878b99b719d0accdb949a
+DIST pmacct-1.7.7.tar.gz 2149629 BLAKE2B 00357cbf1f52452c4a9ee9807e2c18f823019521cc9cb99553fe262826d7343e286694d666c7bab59e62767598ff373b3abafbecfdd43a823ba8784777740643 SHA512 7bc4c48041f023b5cd7ba927722478b0008d751bdb679f44beb2b281f4b16cb0bafb211d0fb947516ca80f86082f1bce578973ec298f4947ffd9d063a44bd00b
diff --git a/net-analyzer/pmacct/pmacct-999999.ebuild b/net-analyzer/pmacct/pmacct-1.7.7.ebuild
index 4446fb29a9c9..687b4ef7d8f2 100644
--- a/net-analyzer/pmacct/pmacct-999999.ebuild
+++ b/net-analyzer/pmacct/pmacct-1.7.7.ebuild
@@ -1,21 +1,27 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-inherit autotools flag-o-matic git-r3 toolchain-funcs
+inherit autotools toolchain-funcs
 
 DESCRIPTION="A network tool to gather IP traffic information"
 HOMEPAGE="http://www.pmacct.net/"
-EGIT_REPO_URI="https://github.com/pmacct/pmacct/"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/pmacct/pmacct"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/pmacct/pmacct/releases/download/v${PV}/${P}.tar.gz
+		http://www.pmacct.net/${P}.tar.gz"
+
+	KEYWORDS="~amd64 ~x86"
+fi
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS=""
-IUSE="
-	+bgp-bins +bmp-bins geoip geoipv2 jansson kafka +l2 mysql ndpi nflog
-	postgres rabbitmq sqlite +st-bins +traffic-bins zmq
-"
+
+IUSE="+bgp-bins +bmp-bins geoip geoipv2 jansson kafka +l2 mysql ndpi nflog postgres rabbitmq sqlite +st-bins +traffic-bins zmq"
+
 REQUIRED_USE="
 	?? ( geoip geoipv2 )
 	kafka? ( jansson )
@@ -41,6 +47,11 @@ RDEPEND="dev-libs/libcdada
 DEPEND="${RDEPEND}"
 BDEPEND="virtual/pkgconfig"
 
+PATCHES=(
+	"${FILESDIR}/${PN}-1.7.4--Werror.patch"
+	"${FILESDIR}/${PN}-1.7.6-nogit.patch"
+)
+
 DOCS=(
 	CONFIG-KEYS ChangeLog FAQS QUICKSTART UPGRADE
 	docs/INTERNALS docs/PLUGINS docs/SIGNALS
@@ -48,34 +59,36 @@ DOCS=(
 
 src_prepare() {
 	default
-	sed -i -e 's|-Werror||g' configure.ac || die
 	eautoreconf
 }
 
 src_configure() {
 	tc-export CC AR RANLIB
-	append-cflags -fcommon
-
-	econf \
-		$(use_enable bgp-bins) \
-		$(use_enable bmp-bins) \
-		$(use_enable geoip) \
-		$(use_enable geoipv2) \
-		$(use_enable jansson) \
-		$(use_enable kafka) \
-		$(use_enable l2) \
-		$(use_enable mysql) \
-		$(use_enable ndpi) \
-		$(use_enable nflog) \
-		$(use_enable postgres pgsql) \
-		$(use_enable rabbitmq) \
-		$(use_enable sqlite sqlite3) \
-		$(use_enable st-bins) \
-		$(use_enable traffic-bins) \
-		$(use_enable zmq) \
-		--without-external-deps \
-		--disable-debug \
+
+	local myeconfargs=(
+		$(use_enable bgp-bins)
+		$(use_enable bmp-bins)
+		$(use_enable geoip)
+		$(use_enable geoipv2)
+		$(use_enable jansson)
+		$(use_enable kafka)
+		$(use_enable l2)
+		$(use_enable mysql)
+		$(use_enable ndpi)
+		$(use_enable nflog)
+		$(use_enable postgres pgsql)
+		$(use_enable rabbitmq)
+		$(use_enable sqlite sqlite3)
+		$(use_enable st-bins)
+		$(use_enable traffic-bins)
+		$(use_enable zmq)
+
+		--without-external-deps
+		--disable-debug
 		--disable-mongodb
+	)
+
+	econf "${myeconfargs[@]}"
 }
 
 src_install() {
diff --git a/net-analyzer/pmacct/pmacct-9999.ebuild b/net-analyzer/pmacct/pmacct-9999.ebuild
new file mode 100644
index 000000000000..687b4ef7d8f2
--- /dev/null
+++ b/net-analyzer/pmacct/pmacct-9999.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="A network tool to gather IP traffic information"
+HOMEPAGE="http://www.pmacct.net/"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/pmacct/pmacct"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/pmacct/pmacct/releases/download/v${PV}/${P}.tar.gz
+		http://www.pmacct.net/${P}.tar.gz"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="+bgp-bins +bmp-bins geoip geoipv2 jansson kafka +l2 mysql ndpi nflog postgres rabbitmq sqlite +st-bins +traffic-bins zmq"
+
+REQUIRED_USE="
+	?? ( geoip geoipv2 )
+	kafka? ( jansson )
+	rabbitmq? ( jansson )
+"
+
+RDEPEND="dev-libs/libcdada
+	net-libs/libpcap
+	geoip? ( dev-libs/geoip )
+	geoipv2? ( dev-libs/libmaxminddb )
+	jansson? ( dev-libs/jansson:= )
+	kafka? ( dev-libs/librdkafka )
+	mysql? (
+		dev-db/mysql-connector-c:0=
+		sys-process/numactl
+	)
+	ndpi? ( >=net-libs/nDPI-3.2:= )
+	nflog? ( net-libs/libnetfilter_log )
+	postgres? ( dev-db/postgresql:* )
+	rabbitmq? ( net-libs/rabbitmq-c )
+	sqlite? ( =dev-db/sqlite-3* )
+	zmq? ( >=net-libs/zeromq-4.2.0:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.7.4--Werror.patch"
+	"${FILESDIR}/${PN}-1.7.6-nogit.patch"
+)
+
+DOCS=(
+	CONFIG-KEYS ChangeLog FAQS QUICKSTART UPGRADE
+	docs/INTERNALS docs/PLUGINS docs/SIGNALS
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC AR RANLIB
+
+	local myeconfargs=(
+		$(use_enable bgp-bins)
+		$(use_enable bmp-bins)
+		$(use_enable geoip)
+		$(use_enable geoipv2)
+		$(use_enable jansson)
+		$(use_enable kafka)
+		$(use_enable l2)
+		$(use_enable mysql)
+		$(use_enable ndpi)
+		$(use_enable nflog)
+		$(use_enable postgres pgsql)
+		$(use_enable rabbitmq)
+		$(use_enable sqlite sqlite3)
+		$(use_enable st-bins)
+		$(use_enable traffic-bins)
+		$(use_enable zmq)
+
+		--without-external-deps
+		--disable-debug
+		--disable-mongodb
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	for dirname in examples sql telemetry; do
+		docinto ${dirname}
+		dodoc -r ${dirname}/*
+	done
+
+	newinitd "${FILESDIR}"/pmacctd-init.d pmacctd
+	newconfd "${FILESDIR}"/pmacctd-conf.d pmacctd
+
+	insinto /etc/pmacctd
+	newins examples/pmacctd-imt.conf.example pmacctd.conf
+}