proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 69 insertions, 0 deletions

diff --git a/net-misc/vino/vino-3.14.2.ebuild b/net-misc/vino/vino-3.14.2.ebuild
new file mode 100644
index 000000000000..32f65b27e679
--- /dev/null
+++ b/net-misc/vino/vino-3.14.2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="yes"
+
+inherit gnome2
+
+DESCRIPTION="An integrated VNC server for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Projects/Vino"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc x86 ~x86-fbsd"
+IUSE="crypt libsecret ipv6 jpeg networkmanager ssl +telepathy zeroconf +zlib"
+# bug #394611; tight encoding requires zlib encoding
+REQUIRED_USE="jpeg? ( zlib )"
+
+# cairo used in vino-fb
+# libSM and libICE used in eggsmclient-xsmp
+RDEPEND="
+	>=dev-libs/glib-2.26:2
+	>=x11-libs/gtk+-3.0.0:3
+	>=dev-libs/libgcrypt-1.1.90:0=
+
+	dev-libs/dbus-glib
+	x11-libs/cairo:=
+	x11-libs/pango[X]
+	x11-libs/libICE
+	x11-libs/libX11
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libSM
+	x11-libs/libXtst
+
+	>=x11-libs/libnotify-0.7.0:=
+
+	crypt? ( >=dev-libs/libgcrypt-1.1.90:0= )
+	libsecret? ( app-crypt/libsecret )
+	jpeg? ( virtual/jpeg:0= )
+	networkmanager? ( >=net-misc/networkmanager-0.7 )
+	ssl? ( >=net-libs/gnutls-2.2.0:= )
+	telepathy? ( >=net-libs/telepathy-glib-0.18 )
+	zeroconf? ( >=net-dns/avahi-0.6:=[dbus] )
+	zlib? ( sys-libs/zlib:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-lang/perl-5
+	>=dev-util/intltool-0.50
+	virtual/pkgconfig
+	app-crypt/libsecret
+"
+# libsecret is always required at build time per bug 322763
+
+src_configure() {
+	gnome2_src_configure \
+		--with-gcrypt \
+		$(use_with crypt gcrypt) \
+		$(use_enable ipv6) \
+		$(use_with jpeg) \
+		$(use_with libsecret secret) \
+		$(use_with networkmanager network-manager) \
+		$(use_with ssl gnutls) \
+		$(use_with telepathy) \
+		$(use_with zeroconf avahi) \
+		$(use_with zlib)
+}