proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 66 insertions, 0 deletions

diff --git a/sci-electronics/gazebo/gazebo-5.1.0.ebuild b/sci-electronics/gazebo/gazebo-5.1.0.ebuild
new file mode 100644
index 000000000000..d1a55a1ed8ff
--- /dev/null
+++ b/sci-electronics/gazebo/gazebo-5.1.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils versionator vcs-snapshot flag-o-matic
+
+DESCRIPTION="A 3D multiple robot simulator with dynamics"
+HOMEPAGE="http://gazebosim.org/"
+SRC_URI="https://bitbucket.org/osrf/gazebo/get/${PN}$(get_major_version)_${PV}.tar.bz2"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="cpu_flags_x86_sse2 libav test"
+
+RDEPEND="
+	>=dev-libs/protobuf-2.3.0
+	virtual/opengl
+	media-libs/openal
+	net-misc/curl
+	dev-libs/tinyxml
+	dev-libs/libtar
+	dev-cpp/tbb
+	>=dev-games/ogre-1.7.4
+	sci-libs/libccd
+	libav? ( media-video/libav:= )
+	!libav? ( media-video/ffmpeg:= )
+	sci-libs/gts
+	>=sci-physics/bullet-2.82
+	>=dev-libs/sdformat-2.3.1
+	dev-qt/qtcore:4
+	dev-qt/qtgui:4
+	dev-libs/boost:=[threads]
+	sci-libs/gdal
+	virtual/libusb:1
+	dev-libs/libspnav
+	media-libs/freeimage
+"
+DEPEND="${RDEPEND}
+	dev-qt/qttest:4
+	app-text/ronn
+	virtual/pkgconfig
+"
+S="${WORKDIR}/${PN}$(get_major_version)_${PV}"
+CMAKE_BUILD_TYPE=RelWithDebInfo
+PATCHES=( "${FILESDIR}/bullet_283.patch" )
+
+src_configure() {
+	# doesnt build without it
+	append-cxxflags "-std=c++11"
+	# doesnt build with as-needed either
+	append-ldflags "-Wl,--no-as-needed"
+
+	has_version '>=sci-physics/bullet-2.83' && append-cppflags "-DLIBBULLET_VERSION_GT_282=1"
+
+	local mycmakeargs=(
+		"-DUSE_UPSTREAM_CFLAGS=OFF"
+		"-DSSE2_FOUND=$(usex cpu_flags_x86_sse2 TRUE FALSE)"
+		"-DUSE_HOST_CFLAGS=FALSE"
+		"-DENABLE_TESTS_COMPILATION=$(usex test TRUE FALSE)"
+		"-DENABLE_SCREEN_TESTS=FALSE"
+	)
+	cmake-utils_src_configure
+}