1 files changed, 61 insertions, 0 deletions
diff --git a/x11-misc/dmenu/dmenu-4.7-r1.ebuild b/x11-misc/dmenu/dmenu-4.7-r1.ebuild
new file mode 100644
index 000000000000..05dc375cb2ba
--- /dev/null
+++ b/x11-misc/dmenu/dmenu-4.7-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit savedconfig toolchain-funcs
+
+DESCRIPTION="a generic, highly customizable, and efficient menu for the X Window System"
+HOMEPAGE="https://tools.suckless.org/dmenu/"
+SRC_URI="https://dl.suckless.org/tools/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="xinerama"
+
+RDEPEND="
+	media-libs/fontconfig
+	x11-libs/libX11
+	x11-libs/libXft
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	xinerama? ( x11-proto/xineramaproto )
+	x11-proto/xproto
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.7-gentoo.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's|^	@|	|g' \
+		-e 's|${CC} -o|$(CC) $(CFLAGS) -o|g' \
+		-e '/^	echo/d' \
+		Makefile || die
+
+	restore_config config.h
+}
+
+src_compile() {
+	emake CC=$(tc-getCC) \
+		"FREETYPEINC=$( $(tc-getPKG_CONFIG) --cflags x11 fontconfig xft 2>/dev/null )" \
+		"FREETYPELIBS=$( $(tc-getPKG_CONFIG) --libs x11 fontconfig xft 2>/dev/null )" \
+		"XINERAMAFLAGS=$(
+			usex xinerama "-DXINERAMA $(
+				$(tc-getPKG_CONFIG) --cflags xinerama 2>/dev/null
+			)" ''
+		)" \
+		"XINERAMALIBS=$(
+			usex xinerama "$( $(tc-getPKG_CONFIG) --libs xinerama 2>/dev/null)" ''
+		)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="/usr" install
+
+	save_config config.h
+}