app-i18n/kinput2: update to EAPI 6

Gentoo-Bug: 621946

Package-Manager: Portage-2.3.6, Repoman-2.3.1

4 files changed, 75 insertions, 70 deletions

diff --git a/app-i18n/kinput2/files/xinput-kinput2 b/app-i18n/kinput2/files/xinput-kinput2
index 16de07ca4f7e..dcb3b63330ac 100644
--- a/app-i18n/kinput2/files/xinput-kinput2
+++ b/app-i18n/kinput2/files/xinput-kinput2
@@ -1,5 +1,5 @@
 XIM=kinput2
-XIM_PROGRAM=@EPREFIX@/usr/bin/kinput2
+XIM_PROGRAM="@EPREFIX@/usr/bin/kinput2"
 XIM_ARGS="-@SERVER@ +kinput -xim"
 GTK_IM_MODULE=xim
 QT_IM_MODULE=xim
diff --git a/app-i18n/kinput2/kinput2-3.1-r1.ebuild b/app-i18n/kinput2/kinput2-3.1-r1.ebuild
index 7d264fb834e1..5e3579baa0df 100644
--- a/app-i18n/kinput2/kinput2-3.1-r1.ebuild
+++ b/app-i18n/kinput2/kinput2-3.1-r1.ebuild
@@ -1,62 +1,68 @@
 # Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-inherit eutils
+EAPI="6"
+
+inherit toolchain-funcs
 
 MY_P="${PN}-v${PV}"
+
 DESCRIPTION="A Japanese input server which supports the XIM protocol"
-HOMEPAGE="http://www.nec.co.jp/canna/"
+HOMEPAGE="http://www.nec.co.jp/canna"
 SRC_URI="ftp://ftp.sra.co.jp/pub/x11/${PN}/${MY_P}.tar.gz"
 
 LICENSE="HPND"
 SLOT="0"
-KEYWORDS="x86 ppc sparc amd64 ppc64"
+KEYWORDS="amd64 ppc ppc64 sparc x86"
 IUSE="freewnn"
 
-RDEPEND="freewnn? ( >=app-i18n/freewnn-1.1.1_alpha19 )
-	!freewnn? ( >=app-i18n/canna-3.5_beta2-r1 )
+RDEPEND="x11-libs/libICE
+	x11-libs/libSM
 	x11-libs/libX11
 	x11-libs/libXaw
+	x11-libs/libXext
 	x11-libs/libXmu
-	x11-libs/libXp
-	x11-libs/libXt"
-
+	x11-libs/libXpm
+	x11-libs/libXt
+	!freewnn? ( app-i18n/canna )
+	freewnn? ( app-i18n/freewnn )"
 DEPEND="${RDEPEND}
 	x11-misc/gccmakedep
-	x11-misc/imake
-	app-text/rman"
-
+	x11-misc/imake"
 S="${WORKDIR}/${MY_P}"
 
-src_unpack() {
-	local mysed=""
+PATCHES=(
+	"${FILESDIR}"/${PN}-gentoo.patch
+	"${FILESDIR}"/${PN}-ppc.patch
+	"${FILESDIR}"/${PN}-segfault.patch
+)
+DOCS=( README NEWS doc/. )
 
-	unpack ${A}
-	cd "${S}"
-	epatch "${FILESDIR}/${PN}-gentoo.patch"
-	epatch "${FILESDIR}/${PN}-ppc.patch"
-	epatch "${FILESDIR}/${PN}-segfault.patch"
+src_prepare() {
+	default
 
-	if use freewnn; then
-		sed -i -e '/\/\* #define UseWnn/s:^:#define UseWnn\n:' Kinput2.conf
-	else
-		sed -i -e '/\/\* #define UseCanna/s:^:#define UseCanna\n:' Kinput2.conf
-	fi
+	sed -i "s|^/\* \(#define Use$(usex freewnn Wnn Canna)\) \*/|\1|" ${PN^k}.conf
 }
 
-src_compile() {
+src_configure() {
 	xmkmf -a || die
+}
+
+src_compile() {
 	emake \
-		XAPPLOADDIR="/usr/share/X11/app-defaults/" \
+		CC="$(tc-getCC)" \
 		CDEBUGFLAGS="${CFLAGS}" \
 		LOCAL_LDFLAGS="${LDFLAGS}" \
-		|| die
+		XAPPLOADDIR="${EPREFIX}/usr/share/X11/app-defaults"
 }
 
 src_install() {
-	emake XAPPLOADDIR="/usr/share/X11/app-defaults/" DESTDIR="${D}" install || die
-	rm -rf "${D}/usr/lib/X11"
-
-	dodoc README NEWS doc/*
+	emake \
+		XAPPLOADDIR="${EPREFIX}/usr/share/X11/app-defaults" \
+		DESTDIR="${D}" \
+		install
+	einstalldocs
 	newman cmd/${PN}.man ${PN}.1
+
+	rm -rf "${ED}"/usr/$(get_libdir)/X11
 }
diff --git a/app-i18n/kinput2/kinput2-3.1-r2.ebuild b/app-i18n/kinput2/kinput2-3.1-r2.ebuild
index d04128071894..724a233a91ec 100644
--- a/app-i18n/kinput2/kinput2-3.1-r2.ebuild
+++ b/app-i18n/kinput2/kinput2-3.1-r2.ebuild
@@ -1,12 +1,14 @@
 # Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="3"
-inherit eutils
+EAPI="6"
+
+inherit toolchain-funcs
 
 MY_P="${PN}-v${PV}"
+
 DESCRIPTION="A Japanese input server which supports the XIM protocol"
-HOMEPAGE="http://www.nec.co.jp/canna/"
+HOMEPAGE="http://www.nec.co.jp/canna"
 SRC_URI="ftp://ftp.sra.co.jp/pub/x11/${PN}/${MY_P}.tar.gz"
 
 LICENSE="HPND"
@@ -14,31 +16,32 @@ SLOT="0"
 KEYWORDS="amd64 ~ppc ~ppc64 ~sparc x86"
 IUSE="freewnn"
 
-RDEPEND="freewnn? ( >=app-i18n/freewnn-1.1.1_alpha19 )
-	!freewnn? ( >=app-i18n/canna-3.5_beta2-r1 )
+RDEPEND="x11-libs/libICE
+	x11-libs/libSM
 	x11-libs/libX11
 	x11-libs/libXaw
+	x11-libs/libXext
 	x11-libs/libXmu
-	x11-libs/libXp
-	x11-libs/libXt"
-
+	x11-libs/libXpm
+	x11-libs/libXt
+	!freewnn? ( app-i18n/canna )
+	freewnn? ( app-i18n/freewnn )"
 DEPEND="${RDEPEND}
 	x11-misc/gccmakedep
-	x11-misc/imake
-	app-text/rman"
-
+	x11-misc/imake"
 S="${WORKDIR}/${MY_P}"
 
+PATCHES=(
+	"${FILESDIR}"/${PN}-gentoo.patch
+	"${FILESDIR}"/${PN}-ppc.patch
+	"${FILESDIR}"/${PN}-segfault.patch
+)
+DOCS=( README NEWS doc/. )
+
 src_prepare() {
-	epatch "${FILESDIR}/${PN}-gentoo.patch"
-	epatch "${FILESDIR}/${PN}-ppc.patch"
-	epatch "${FILESDIR}/${PN}-segfault.patch"
+	default
 
-	if use freewnn; then
-		sed -i -e '/\/\* #define UseWnn/s:^:#define UseWnn\n:' Kinput2.conf || die
-	else
-		sed -i -e '/\/\* #define UseCanna/s:^:#define UseCanna\n:' Kinput2.conf || die
-	fi
+	sed -i "s|^/\* \(#define Use$(usex freewnn Wnn Canna)\) \*/|\1|" ${PN^k}.conf
 }
 
 src_configure() {
@@ -47,30 +50,26 @@ src_configure() {
 
 src_compile() {
 	emake \
-		XAPPLOADDIR="${EPREFIX}/usr/share/X11/app-defaults/" \
+		CC="$(tc-getCC)" \
 		CDEBUGFLAGS="${CFLAGS}" \
 		LOCAL_LDFLAGS="${LDFLAGS}" \
-		|| die
+		XAPPLOADDIR="${EPREFIX}/usr/share/X11/app-defaults"
 }
 
 src_install() {
-	emake XAPPLOADDIR="/usr/share/X11/app-defaults/" DESTDIR="${D}" install || die
-	rm -rf "${ED}/usr/lib/X11" || die
+	emake \
+		XAPPLOADDIR="${EPREFIX}/usr/share/X11/app-defaults" \
+		DESTDIR="${D}" \
+		install
+	einstalldocs
+	newman cmd/${PN}.man ${PN}.1
 
-	local server
-	if use freewnn; then
-		server="wnn"
-	else
-		server="canna"
-	fi
+	rm -rf "${ED}"/usr/$(get_libdir)/X11
 
 	insinto /etc/X11/xinit/xinput.d
 	sed \
 		-e "s:@EPREFIX@:${EPREFIX}:g" \
-		-e "s:@SERVER@:${server}:g" \
-		"${FILESDIR}/xinput-kinput2" > "${T}/kinput2.conf" || die
-	doins "${T}/kinput2.conf" || die
-
-	dodoc README NEWS doc/* || die
-	newman cmd/${PN}.man ${PN}.1 || die
+		-e "s:@SERVER@:$(usex freewnn wnn canna):g" \
+		"${FILESDIR}"/xinput-${PN} > "${T}"/${PN}.conf
+	doins "${T}"/${PN}.conf
 }
diff --git a/app-i18n/kinput2/metadata.xml b/app-i18n/kinput2/metadata.xml
index c921b96adf6c..e1a49f498885 100644
--- a/app-i18n/kinput2/metadata.xml
+++ b/app-i18n/kinput2/metadata.xml
@@ -1,8 +1,8 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<maintainer type="project">
-	<email>cjk@gentoo.org</email>
-	<name>Cjk</name>
-</maintainer>
+  <maintainer type="project">
+    <email>cjk@gentoo.org</email>
+    <name>Cjk</name>
+  </maintainer>
 </pkgmetadata>