app-admin/consul: Version bump to 1.2.3

Package-Manager: Portage-2.3.49, Repoman-2.3.10

2 files changed, 70 insertions, 0 deletions

diff --git a/app-admin/consul/Manifest b/app-admin/consul/Manifest
index fc2b1948023e..6ac4943e7374 100644
--- a/app-admin/consul/Manifest
+++ b/app-admin/consul/Manifest
@@ -1 +1,2 @@
 DIST consul-1.2.2.tar.gz 15789375 BLAKE2B 8a0af370568f6fcb90334b147bd84e479efb682ed6c58d63dd56f3554f9e6538d37963ac825bb8598eef8948492feec688b8266733223d1557dbce9704daef35 SHA512 715f69e7b36d0070ea4e602dc50f51aa2547dbbbbb07cce985da79d1e201c6e84dade8a7c810e3602f88cfbd30e063669076954d2541810a18a0c9e7c9ff8458
+DIST consul-1.2.3.tar.gz 18428593 BLAKE2B 14582bf9668e4f2a1c8c443cb01d7b9780c9bc414ff226907335f3873c135b77566898649d16b352ef21ee9300c290338f59672c5fb2b187694aea97b8735dec SHA512 71a7dbfc031df4a96faf2ddd829f289e96adefd0e0087208bbdd26e742a24e3da05fceea4181eb915703ad3323ed5b02bf74eb3fdfbed1e9a1afa2f74acb2a34
diff --git a/app-admin/consul/consul-1.2.3.ebuild b/app-admin/consul/consul-1.2.3.ebuild
new file mode 100644
index 000000000000..5c900d4ab45d
--- /dev/null
+++ b/app-admin/consul/consul-1.2.3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit golang-vcs-snapshot systemd user
+GIT_COMMIT="48d287e"
+KEYWORDS="~amd64"
+EGO_PN="github.com/hashicorp/consul"
+DESCRIPTION="A tool for service discovery, monitoring and configuration"
+HOMEPAGE="https://www.consul.io"
+SRC_URI="https://github.com/hashicorp/consul/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MPL-2.0"
+IUSE=""
+
+RESTRICT="test"
+
+DEPEND="dev-go/gox
+	>=dev-lang/go-1.9:=
+	>=dev-go/go-tools-0_pre20160121"
+RDEPEND=""
+
+pkg_setup() {
+	enewgroup consul
+	enewuser consul -1 -1 /var/lib/${PN} consul
+}
+
+src_prepare() {
+	default
+
+	sed -e 's:go get -u -v $(GOTOOLS)::' \
+		-e 's:vendorfmt dev-build:dev-build:' \
+		-i "src/${EGO_PN}/GNUmakefile" || die
+}
+
+src_compile() {
+	# The dev target sets causes build.sh to set appropriate XC_OS
+	# and XC_ARCH, and skips generation of an unused zip file,
+	# avoiding a dependency on app-arch/zip.
+	GOPATH="${S}" \
+	GOBIN="${S}/bin" \
+	GIT_DESCRIBE="v${PV}" \
+	GIT_DIRTY="" \
+	GIT_COMMIT="${GIT_COMMIT}" \
+	emake -C "src/${EGO_PN}" dev-build
+}
+
+src_install() {
+	local x
+
+	dobin bin/consul
+
+	keepdir /etc/consul.d
+	insinto /etc/consul.d
+	doins "${FILESDIR}/"*.json.example
+
+	for x in /var/{lib,log}/${PN}; do
+		keepdir "${x}"
+		fowners consul:consul "${x}"
+	done
+
+	newinitd "${FILESDIR}/consul.initd" "${PN}"
+	newconfd "${FILESDIR}/consul.confd" "${PN}"
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+	systemd_dounit "${FILESDIR}/consul.service"
+}