app-admin/monit: Bump to version 5.25.3

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

1 files changed, 59 insertions, 0 deletions

diff --git a/app-admin/monit/monit-5.25.3.ebuild b/app-admin/monit/monit-5.25.3.ebuild
new file mode 100644
index 000000000000..71d8de2c4988
--- /dev/null
+++ b/app-admin/monit/monit-5.25.3.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit bash-completion-r1 pam systemd
+
+DESCRIPTION="Monitoring and managing daemons or similar programs running on a Unix system"
+HOMEPAGE="http://mmonit.com/monit/"
+SRC_URI="http://mmonit.com/monit/dist/${P}.tar.gz"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux"
+IUSE="ipv6 libressl pam ssl"
+
+RDEPEND="
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)"
+DEPEND="${RDEPEND}
+	pam? ( virtual/pam )"
+BDEPEND="
+	sys-devel/flex
+	sys-devel/bison
+"
+
+src_prepare() {
+	default
+	sed -i -e '/^INSTALL_PROG/s/-s//' Makefile.in || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with ipv6)
+		$(use_with pam)
+		$(use_with ssl)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	dodoc README
+
+	insinto /etc; insopts -m600; doins monitrc
+	newinitd "${FILESDIR}"/monit.initd-5.0-r1 monit
+	systemd_dounit "${FILESDIR}"/${PN}.service
+
+	use pam && newpamd "${FILESDIR}"/${PN}.pamd ${PN}
+
+	dobashcomp system/bash/monit
+}
+
+pkg_postinst() {
+	elog "Sample configurations are available at:"
+	elog "http://mmonit.com/monit/documentation/"
+}