proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 61 insertions, 0 deletions

diff --git a/app-arch/zip/zip-3.0-r2.ebuild b/app-arch/zip/zip-3.0-r2.ebuild
new file mode 100644
index 000000000000..2547eca56685
--- /dev/null
+++ b/app-arch/zip/zip-3.0-r2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="4"
+inherit toolchain-funcs eutils flag-o-matic
+
+MY_P="${PN}${PV//.}"
+DESCRIPTION="Info ZIP (encryption support)"
+HOMEPAGE="http://www.info-zip.org/"
+SRC_URI="mirror://sourceforge/infozip/${MY_P}.zip"
+
+LICENSE="Info-ZIP"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~arm-linux"
+IUSE="bzip2 crypt natspec unicode"
+
+RDEPEND="bzip2? ( app-arch/bzip2 )
+	natspec? ( dev-libs/libnatspec )"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-3.0-no-crypt.patch #238398
+	epatch "${FILESDIR}"/${PN}-3.0-pic.patch
+	epatch "${FILESDIR}"/${PN}-3.0-exec-stack.patch
+	epatch "${FILESDIR}"/${PN}-3.0-build.patch
+	use natspec && epatch "${FILESDIR}"/${PN}-3.0-natspec.patch #275244
+}
+
+src_configure() {
+	append-cppflags \
+		-DLARGE_FILE_SUPPORT \
+		-DUIDGID_NOT_16BIT \
+		-D$(usex bzip2 '' NO)BZIP2_SUPPORT \
+		-D$(usex crypt '' NO)CRYPT \
+		-D$(usex unicode '' NO)UNICODE_SUPPORT
+	# Third arg disables bzip2 logic as we handle it ourselves above.
+	sh ./unix/configure "$(tc-getCC)" "-I. -DUNIX ${CFLAGS} ${CPPFLAGS}" "${T}" || die
+	if use bzip2 ; then
+		sed -i -e "s:LFLAGS2=:&'-lbz2 ':" flags || die
+	fi
+}
+
+src_compile() {
+	emake \
+		CPP="$(tc-getCPP)" \
+		-f unix/Makefile generic
+}
+
+src_install() {
+	dobin zip zipnote zipsplit
+	doman man/zip{,note,split}.1
+	if use crypt ; then
+		dobin zipcloak
+		doman man/zipcloak.1
+	fi
+	dodoc BUGS CHANGES README* TODO WHATSNEW WHERE proginfo/*.txt
+}