app-backup/borgbackup: version bump to 1.1.8

Signed-off-by: Anthony G. Basile <blueness@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11
Signed-off-by: Anthony G. Basile <blueness@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/app-backup/borgbackup/borgbackup-1.1.8.ebuild b/app-backup/borgbackup/borgbackup-1.1.8.ebuild
new file mode 100644
index 000000000000..15ee3092744c
--- /dev/null
+++ b/app-backup/borgbackup/borgbackup-1.1.8.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit distutils-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/${PN}/borg.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Deduplicating backup program with compression and authenticated encryption"
+HOMEPAGE="https://borgbackup.readthedocs.io/"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="libressl"
+
+# Unfortunately we have a file conflict with app-office/borg, bug #580402
+RDEPEND="
+	!!app-office/borg
+	app-arch/lz4
+	dev-python/llfuse[${PYTHON_USEDEP}]
+	dev-python/msgpack[${PYTHON_USEDEP}]
+	dev-python/pyzmq[${PYTHON_USEDEP}]
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+"
+
+DEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	${RDEPEND}
+"
+
+python_prepare_all() {
+	# allow use of new (renamed) msgpack
+	sed -i "s|'msgpack-python.*',||g" setup.py || die
+	distutils-r1_python_prepare_all
+}