proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 74 insertions, 0 deletions

diff --git a/app-backup/deja-dup/deja-dup-34.0.ebuild b/app-backup/deja-dup/deja-dup-34.0.ebuild
new file mode 100644
index 000000000000..804305cd9154
--- /dev/null
+++ b/app-backup/deja-dup/deja-dup-34.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+GNOME2_LA_PUNT="yes"
+
+VALA_MIN_API_VERSION="0.22" # for >=gtk+-3.10
+
+inherit cmake-utils eutils gnome2 vala
+
+DESCRIPTION="Simple backup tool using duplicity back-end"
+HOMEPAGE="https://launchpad.net/deja-dup/"
+SRC_URI="http://launchpad.net/${PN}/34/${PV}/+download/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nautilus test"
+
+RESTRICT="test"
+
+COMMON_DEPEND="
+	app-crypt/libsecret[vala]
+	>=dev-libs/glib-2.34:2
+	>=dev-libs/libpeas-1.0
+	>=x11-libs/gtk+-3.10:3
+	>=x11-libs/libnotify-0.7
+
+	>=app-backup/duplicity-0.6.23
+	dev-libs/dbus-glib
+
+	nautilus? ( gnome-base/nautilus )"
+RDEPEND="${COMMON_DEPEND}
+	gnome-base/dconf
+	gnome-base/gvfs[fuse]"
+DEPEND="${COMMON_DEPEND}
+	app-text/yelp-tools
+	$(vala_depend)
+	dev-perl/Locale-gettext
+	virtual/pkgconfig
+	dev-util/intltool
+	sys-devel/gettext"
+
+src_prepare() {
+	sed \
+		-e '/RPATH/s:PKG_LIBEXECDIR:PKG_LIBDIR:g' \
+		-i CMakeLists.txt || die
+	vala_src_prepare
+	gnome2_src_prepare
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DVALA_EXECUTABLE="${VALAC}"
+		-DENABLE_CCPANEL=OFF
+		-DENABLE_UNITY=OFF
+		-DENABLE_UNITY_CCPANEL=OFF
+		-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}"/etc
+		$(cmake-utils_use_enable nautilus)
+		$(cmake-utils_use_enable test TESTING)
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+}