app-crypt/kbfs: Add keybase-redirector

Package-Manager: Portage-2.3.40, Repoman-2.3.9

1 files changed, 46 insertions, 0 deletions

diff --git a/app-crypt/kbfs/kbfs-2.0.0-r1.ebuild b/app-crypt/kbfs/kbfs-2.0.0-r1.ebuild
new file mode 100644
index 000000000000..c6b4d2bbe676
--- /dev/null
+++ b/app-crypt/kbfs/kbfs-2.0.0-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit golang-build systemd
+
+DESCRIPTION="Keybase Filesystem (KBFS)"
+HOMEPAGE="https://keybase.io/docs/kbfs"
+SRC_URI="https://github.com/keybase/kbfs/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND=""
+RDEPEND="
+	app-crypt/gnupg
+	sys-fs/fuse
+	"
+
+src_unpack() {
+	unpack "${P}.tar.gz"
+	mkdir -vp "${S}/src/github.com/keybase" || die
+	ln -vs "${S}" "${S}/src/github.com/keybase/kbfs" || die
+}
+
+src_compile() {
+	EGO_PN="github.com/keybase/kbfs/kbfsfuse" \
+		EGO_BUILD_FLAGS="-tags production -o ${T}/kbfsfuse" \
+		golang-build_src_compile
+	EGO_PN="github.com/keybase/kbfs/kbfsgit/git-remote-keybase" \
+		EGO_BUILD_FLAGS="-tags production -o ${T}/git-remote-keybase" \
+		golang-build_src_compile
+	EGO_PN="github.com/keybase/kbfs/redirector" \
+		EGO_BUILD_FLAGS="-tags production -o ${T}/keybase-redirector" \
+		golang-build_src_compile
+}
+
+src_install() {
+	dobin "${T}/kbfsfuse"
+	dobin "${T}/git-remote-keybase"
+	dobin "${T}/keybase-redirector"
+	systemd_douserunit "${S}/packaging/linux/systemd/kbfs.service"
+}