app-doc/devmanual: New snapshot 0_pre20220326

Signed-off-by: Ulrich Müller <ulm@gentoo.org>

3 files changed, 62 insertions, 1 deletions

diff --git a/app-doc/devmanual/Manifest b/app-doc/devmanual/Manifest
index 57a22b2e3638..2dc0c6325afe 100644
--- a/app-doc/devmanual/Manifest
+++ b/app-doc/devmanual/Manifest
@@ -1,2 +1,3 @@
 DIST devmanual-0_pre20200207.tar.xz 163940 BLAKE2B c6cf856a8f6c80b500466e27cc4106c070cff2dcf8c89d58c9ca90d03cb34a1e6a2048cb99364993f224f3497309fc24207dc44f9c14ece37c49aa602480dac0 SHA512 f6a88312e2030bf4d9fcf64bf1f38397087cb151aa41cd0c254cfc6251e4d5b291e3b361094a7c1d5fdb16e40c1702c0f0b7460ba230bfb217ad733f400c9089
 DIST devmanual-0_pre20210118.tar.xz 165552 BLAKE2B 17b11ab8b5ec31b93fca95c472e7d137157c3d7629b80be26648d5b77f6a6a0709d1a622a079207695fe48cd9d24d48f5ece0a24259106547d84e7c47cb2199b SHA512 2cf40936ab6ee0acda6f71d44d4cbff03ed195688f172d749b32dab9edde005ab9c4ad28d84f7ad01fc82e0fb8a9441cba20c4c7435f21067abf49fe8da739ff
+DIST devmanual-0_pre20220326.tar.xz 183228 BLAKE2B 67ab1a24e8f1043f2d7938a76f4d819ecfaffaf3516cf5ce9eff20ac0e481c60be06c83c4adc3835e6ee66c44def290aa682567662dbf7a7a7057b0d168e1677 SHA512 364fe3504ba424201b450e08fe2043e55d1067c3603c4d3248112117461a4ab667d50f82deac9daaf50e28ea5d996c1ae08668d55b7379915cc175f66edddf9b
diff --git a/app-doc/devmanual/devmanual-0_pre20220326.ebuild b/app-doc/devmanual/devmanual-0_pre20220326.ebuild
new file mode 100644
index 000000000000..f4df71ec1d10
--- /dev/null
+++ b/app-doc/devmanual/devmanual-0_pre20220326.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="xml"
+inherit python-any-r1 readme.gentoo-r1
+
+DESCRIPTION="The Gentoo Development Guide"
+HOMEPAGE="https://devmanual.gentoo.org/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/devmanual.git"
+else
+	# "make dist" in devmanual repo
+	SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
+	S="${WORKDIR}/${PN}"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+fi
+
+LICENSE="CC-BY-SA-4.0"
+SLOT="0"
+IUSE="+offline test"
+RESTRICT="!test? ( test )"
+
+BDEPEND=">=dev-libs/libxml2-2.9.12
+	dev-libs/libxslt
+	gnome-base/librsvg
+	media-fonts/open-sans
+	${PYTHON_DEPS}
+	test? ( >=app-text/htmltidy-5.8.0 )"
+
+PATCHES=( "${FILESDIR}"/${PN}-eclasses.patch )
+
+src_compile() {
+	emake OFFLINE=$(usex offline 1 0)
+}
+
+src_install() {
+	emake OFFLINE=$(usex offline 1 0) \
+		DESTDIR="${D}" \
+		htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	local DOC_CONTENTS="In order to browse the Gentoo Development Guide in
+		offline mode, point your browser to the following url:
+		file://${EPREFIX}/usr/share/doc/${PF}/html/index.html"
+	if ! has_version app-doc/eclass-manpages; then
+		DOC_CONTENTS+="\\n\\nThe offline version of the devmanual does not
+			include the documentation for the eclasses. If you need it,
+			then emerge app-doc/eclass-manpages."
+	fi
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}
diff --git a/app-doc/devmanual/devmanual-9999.ebuild b/app-doc/devmanual/devmanual-9999.ebuild
index 43a09c7515e2..f4df71ec1d10 100644
--- a/app-doc/devmanual/devmanual-9999.ebuild
+++ b/app-doc/devmanual/devmanual-9999.ebuild
@@ -17,7 +17,7 @@ else
 	# "make dist" in devmanual repo
 	SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
 	S="${WORKDIR}/${PN}"
-	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-macos"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
 fi
 
 LICENSE="CC-BY-SA-4.0"