proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 72 insertions, 0 deletions

diff --git a/app-editors/nano/nano-2.3.2.ebuild b/app-editors/nano/nano-2.3.2.ebuild
new file mode 100644
index 000000000000..3758ea421a77
--- /dev/null
+++ b/app-editors/nano/nano-2.3.2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="3"
+
+inherit eutils autotools
+if [[ ${PV} == "9999" ]] ; then
+	ESVN_REPO_URI="svn://svn.savannah.gnu.org/nano/trunk/nano"
+	inherit subversion autotools
+else
+	MY_P=${PN}-${PV/_}
+	SRC_URI="http://www.nano-editor.org/dist/v${PV:0:3}/${MY_P}.tar.gz"
+fi
+
+DESCRIPTION="GNU GPL'd Pico clone with more functionality"
+HOMEPAGE="http://www.nano-editor.org/ http://www.gentoo.org/doc/en/nano-basics-guide.xml"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="debug justify +magic minimal ncurses nls slang spell unicode"
+
+RDEPEND=">=sys-libs/ncurses-5.9-r1[unicode?]
+	magic? ( sys-apps/file )
+	nls? ( virtual/libintl )
+	!ncurses? ( slang? ( sys-libs/slang ) )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+	virtual/pkgconfig"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.3.1-ncurses-pkg-config.patch
+	epatch "${FILESDIR}"/${PN}-2.3.2-bind-unbind-docs.patch
+	epatch "${FILESDIR}"/${PN}-2.3.1-{shell,gentoo}-nanorc.patch
+	eautoreconf
+}
+
+src_configure() {
+	eval export ac_cv_{header_magic_h,lib_magic_magic_open}=$(usex magic)
+	local myconf=()
+	case ${CHOST} in
+	*-gnu*|*-uclibc*) myconf+=( "--with-wordbounds" ) ;; #467848
+	esac
+	econf \
+		--bindir="${EPREFIX}"/bin \
+		$(use_enable !minimal color) \
+		$(use_enable !minimal multibuffer) \
+		$(use_enable !minimal nanorc) \
+		--disable-wrapping-as-root \
+		$(use_enable spell speller) \
+		$(use_enable justify) \
+		$(use_enable debug) \
+		$(use_enable nls) \
+		$(use_enable unicode utf8) \
+		$(use_enable minimal tiny) \
+		$(usex ncurses --without-slang $(use_with slang)) \
+		"${myconf[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	rm -rf "${ED}"/usr/share/nano/man-html
+
+	dodoc ChangeLog README doc/nanorc.sample AUTHORS BUGS NEWS TODO
+	dohtml doc/faq.html
+	insinto /etc
+	newins doc/nanorc.sample nanorc
+
+	dodir /usr/bin
+	dosym /bin/nano /usr/bin/nano
+}