app-editors/nano: drop 7.0-r1

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 0 insertions, 112 deletions

diff --git a/app-editors/nano/Manifest b/app-editors/nano/Manifest
index f63ee4d4bcf6..18a4df697156 100644
--- a/app-editors/nano/Manifest
+++ b/app-editors/nano/Manifest
@@ -1,3 +1,2 @@
 DIST nano-6.4.tar.xz 1593804 BLAKE2B b59ff7a741ce4c8b31afdbbfaf1d704cccbceddcd7f1421f30a6dd40495ec456ca891aeb9777c070c6cce4e9c594f83798ff0cdacdfe06e81b0aa0b700033da3 SHA512 cff2d9d90f1a23ab8905320e651f8bbc9d38046153a4f64bbc21927687d9628135915468b00b28f88a0eb7d395d1bcb0b9b7abcf367e5a46a5f3da01d8d6e72b
-DIST nano-7.0.tar.xz 1598528 BLAKE2B 5212aa2a65cc7bccb33ebd66934e53ea7c6bd739ceae94796397bd193698453417eae2a5cf63c995e90aa077795f9bcf70568a35208716a09c9a6d89d75ff409 SHA512 927db4dec1fcde316104a59ab208ffadea52a65c63888187794d4b47c5d49b591c39d490fdc31255b82f04d77a4321b2f6bb150022a5f88dd3c2500df327b983
 DIST nano-7.1.tar.xz 1605272 BLAKE2B cc606a04b34e723da01326d617b50f79711d0b35034b3e75f410fa7e277ba3eddbb1a408a80255533d2fa953f23fee745979363d5621b63a79bd89b29d8d528e SHA512 e3226df636d3ae1d94e2907ce8bbdb8de69eb45afd02fb1c83e275a1dcc288081809041adbfdade35a580bcb9f9632d21a45d764b43d22b3e4cfd87c7757c4e0
diff --git a/app-editors/nano/nano-7.0-r1.ebuild b/app-editors/nano/nano-7.0-r1.ebuild
deleted file mode 100644
index 7cdc35604620..000000000000
--- a/app-editors/nano/nano-7.0-r1.ebuild
+++ /dev/null
@@ -1,111 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit flag-o-matic
-
-if [[ ${PV} == 9999 ]] ; then
-	EGIT_REPO_URI="https://git.savannah.gnu.org/git/nano.git"
-	inherit autotools git-r3
-else
-	MY_P="${PN}-${PV/_}"
-	SRC_URI="https://www.nano-editor.org/dist/v${PV:0:1}/${MY_P}.tar.xz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-fi
-
-DESCRIPTION="GNU GPL'd Pico clone with more functionality"
-HOMEPAGE="https://www.nano-editor.org/ https://wiki.gentoo.org/wiki/Nano/Basics_Guide"
-
-LICENSE="GPL-3+ LGPL-2.1+ || ( GPL-3+ FDL-1.2+ )"
-SLOT="0"
-IUSE="debug justify magic minimal ncurses nls +spell static unicode"
-
-LIB_DEPEND="
-	>=sys-libs/ncurses-5.9-r1:=[unicode(+)?]
-	sys-libs/ncurses:=[static-libs(+)]
-	magic? ( sys-apps/file[static-libs(+)] )
-	nls? ( virtual/libintl )
-"
-RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )"
-DEPEND="
-	${RDEPEND}
-	static? ( ${LIB_DEPEND} )
-"
-BDEPEND="
-	nls? ( sys-devel/gettext )
-	virtual/pkgconfig
-"
-
-REQUIRED_USE="
-	magic? ( !minimal )
-"
-
-src_prepare() {
-	default
-
-	if [[ ${PV} == 9999 ]] ; then
-		eautoreconf
-	fi
-}
-
-src_configure() {
-	use static && append-ldflags -static
-
-	local myconfargs=(
-		--bindir="${EPREFIX}"/bin
-		--htmldir=/trash
-		$(use_enable !minimal color)
-		$(use_enable !minimal multibuffer)
-		$(use_enable !minimal nanorc)
-		$(use_enable magic libmagic)
-		$(use_enable spell speller)
-		$(use_enable justify)
-		$(use_enable debug)
-		$(use_enable nls)
-		$(use_enable unicode utf8)
-		$(use_enable minimal tiny)
-	)
-
-	econf "${myconfargs[@]}"
-}
-
-src_install() {
-	default
-
-	# Don't use "${ED}" here or things break (#654534)
-	rm -r "${D}"/trash || die
-
-	dodoc doc/sample.nanorc
-	docinto html
-	dodoc doc/faq.html
-	insinto /etc
-	newins doc/sample.nanorc nanorc
-
-	if ! use minimal ; then
-		# Enable colorization by default.
-		sed -i \
-			-e '/^# include /s:# *::' \
-			"${ED}"/etc/nanorc || die
-
-		# Since nano-5.0 these are no longer being "enabled" by default
-		# (bug #736848)
-		local rcdir="/usr/share/nano"
-		mv "${ED}"${rcdir}/extra/* "${ED}"/${rcdir}/ || die
-		rmdir "${ED}"${rcdir}/extra || die
-
-		insinto "${rcdir}"
-		newins "${FILESDIR}/gentoo.nanorc-r1" gentoo.nanorc
-	fi
-}
-
-pkg_postrm() {
-	[[ -n ${REPLACED_BY_VERSION} ]] && return
-
-	local e
-	e=$(unset EDITOR; . "${EROOT}"/etc/profile &>/dev/null; echo "${EDITOR}")
-	if [[ ${e##*/} == nano ]]; then
-		ewarn "The EDITOR variable is still set to ${e}."
-		ewarn "You can update it with \"eselect editor\"."
-	fi
-}