app-emulation/runc: version bump

Package-Manager: portage-2.2.26
Signed-off-by: Doug Goldstein <cardoe@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/app-emulation/runc/runc-9999.ebuild b/app-emulation/runc/runc-9999.ebuild
new file mode 100644
index 000000000000..ac34b8ee2d16
--- /dev/null
+++ b/app-emulation/runc/runc-9999.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit eutils multilib
+
+DESCRIPTION="runc container cli tools"
+HOMEPAGE="http://runc.io"
+
+GITHUB_URI="github.com/opencontainers/runc"
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="git://${GITHUB_URI}.git"
+	inherit git-r3
+else
+	SRC_URI="https://${GITHUB_URI}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="+seccomp"
+
+DEPEND=">=dev-lang/go-1.4:="
+RDEPEND="seccomp? ( sys-libs/libseccomp )"
+
+src_compile() {
+	# Taken from app-emulation/docker-1.7.0-r1
+	export CGO_CFLAGS="-I${ROOT}/usr/include"
+	export CGO_LDFLAGS="-L${ROOT}/usr/$(get_libdir)"
+
+	# Setup GOPATH so things build
+	rm -rf .gopath
+	mkdir -p .gopath/src/"$(dirname "${GITHUB_URI}")"
+	ln -sf ../../../.. .gopath/src/"${GITHUB_URI}"
+	export GOPATH="${PWD}/.gopath:${PWD}/vendor"
+
+	# build up optional flags
+	local options=( $(usex seccomp "seccomp") )
+
+	emake BUILDTAGS="${options[@]}"
+}
+
+src_install() {
+	dobin runc
+}