app-metrics/elasticsearch_exporter: Version bump to 1.1.0_rc1

Package-Manager: Portage-2.3.68, Repoman-2.3.16
Signed-off-by: Manuel Rüger <mrueg@gentoo.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/app-metrics/elasticsearch_exporter/elasticsearch_exporter-1.1.0_rc1.ebuild b/app-metrics/elasticsearch_exporter/elasticsearch_exporter-1.1.0_rc1.ebuild
new file mode 100644
index 000000000000..8ac76f6636db
--- /dev/null
+++ b/app-metrics/elasticsearch_exporter/elasticsearch_exporter-1.1.0_rc1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit user golang-build golang-vcs-snapshot
+
+MY_PV=${PV/_/}
+
+EGO_PN="github.com/justwatchcom/elasticsearch_exporter"
+EXPORTER_COMMIT="c0ec042"
+ARCHIVE_URI="https://${EGO_PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
+
+DESCRIPTION="Elasticsearch stats exporter for Prometheus"
+HOMEPAGE="https://github.com/justwatchcom/elasticsearch_exporter"
+SRC_URI="${ARCHIVE_URI}"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+DEPEND="dev-util/promu"
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 -1 ${PN}
+}
+
+src_prepare() {
+	default
+	sed -i -e "/-s$/d" -e "s/{{.Revision}}/${EXPORTER_COMMIT}/" src/${EGO_PN}/.promu.yml || die
+}
+
+src_compile() {
+	pushd src/${EGO_PN} || die
+	mkdir -p bin || die
+	GOPATH="${S}" promu build -v --prefix bin || die
+	popd || die
+}
+
+src_install() {
+	pushd src/${EGO_PN} || die
+	dobin bin/elasticsearch_exporter
+	dodoc {README,CHANGELOG}.md
+	popd || die
+	keepdir /var/log/elasticsearch_exporter
+	fowners ${PN}:${PN} /var/log/elasticsearch_exporter
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}