app-misc/cmatrix: Waterproof font .uuid file creation

Lack of file /usr/share/fonts/misc/.uuid
would cause sandbox violation issues in other packages.
font_pkg_postinst take care of its creation now.

Closes: https://bugs.gentoo.org/665008

Package-Manager: Portage-2.3.49, Repoman-2.3.10

1 files changed, 55 insertions, 0 deletions

diff --git a/app-misc/cmatrix/cmatrix-1.2a-r4.ebuild b/app-misc/cmatrix/cmatrix-1.2a-r4.ebuild
new file mode 100644
index 000000000000..c500c953e5d7
--- /dev/null
+++ b/app-misc/cmatrix/cmatrix-1.2a-r4.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools font
+
+DESCRIPTION="An ncurses based app to show a scrolling screen from the Matrix"
+HOMEPAGE="https://sourceforge.net/projects/cmatrix/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="X"
+
+DEPEND="
+	X? ( x11-apps/mkfontdir )
+	sys-libs/ncurses:0="
+
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gentoo.patch
+	"${FILESDIR}"/${P}-tinfo.patch
+)
+
+src_prepare() {
+	default
+
+	use X && eapply "${FILESDIR}"/${P}-fontdir.patch
+
+	eautoreconf
+}
+
+src_install() {
+	dodir /usr/share/consolefonts
+	dodir /usr/lib/kbd/consolefonts
+	use X && dodir /usr/share/fonts/misc
+
+	default
+}
+
+pkg_postinst() {
+	if use X; then
+		if [[ -d "${ROOT}"usr/share/fonts/misc ]] ; then
+			einfo ">>> Running mkfontdir on ${ROOT}usr/share/fonts/misc"
+			mkfontdir "${ROOT}"usr/share/fonts/misc
+		fi
+		font_pkg_postinst
+	fi
+}
+
+pkg_postrm() {
+	use X && font_pkg_postrm
+}