proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 69 insertions, 0 deletions

diff --git a/dev-libs/cyberjack/cyberjack-3.99.5_p03-r1.ebuild b/dev-libs/cyberjack/cyberjack-3.99.5_p03-r1.ebuild
new file mode 100644
index 000000000000..da4ac2a28b0d
--- /dev/null
+++ b/dev-libs/cyberjack/cyberjack-3.99.5_p03-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils linux-info toolchain-funcs udev
+
+MY_P=pcsc-${PN}_${PV/_p/final.SP}
+
+DESCRIPTION="REINER SCT cyberJack pinpad/e-com USB user space driver library"
+HOMEPAGE="http://www.reiner-sct.de/ http://www.libchipcard.de/"
+SRC_URI="http://support.reiner-sct.de/downloads/LINUX/V${PV/_p/_SP}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="fox udev xml"
+
+COMMON_DEPEND="sys-apps/pcsc-lite
+	virtual/libusb:1
+	fox? ( >=x11-libs/fox-1.6 )
+	xml? ( dev-libs/libxml2 )"
+RDEPEND="${COMMON_DEPEND}
+	udev? ( virtual/udev )"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P/_/-}
+
+DOCS="ChangeLog NEWS doc/*.txt"
+
+pkg_setup() {
+	CONFIG_CHECK="~USB_SERIAL_CYBERJACK"
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-gcc47.patch
+}
+
+src_configure() {
+	econf \
+		--mandir=/usr/share/man/man8 \
+		--sysconfdir=/etc/${PN} \
+		--disable-hal \
+		--enable-pcsc \
+		$(use_enable xml xml2) \
+		$(use_enable fox) \
+		--with-usbdropdir="$($(tc-getPKG_CONFIG) libpcsclite --variable=usbdropdir)"
+}
+
+src_install() {
+	default
+
+	rm -f "${ED}"/usr/lib*/${PN}/pcscd_init.diff
+	prune_libtool_files --all
+
+	use udev && udev_newrules "${FILESDIR}"/${PN}.rules 92-${PN}.rules #388329
+}
+
+pkg_postinst() {
+	local conf="${EROOT}etc/${PN}/${PN}.conf"
+	elog
+	elog "To configure logging, key beep behaviour etc. you need to"
+	elog "copy ${conf}.default"
+	elog "to ${conf}"
+	elog "and modify the latter as needed."
+	elog
+}