dev-libs/libconfig: Version 1.7.2.

Package-Manager: Portage-2.3.24, Repoman-2.3.6

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-libs/libconfig/libconfig-1.7.2.ebuild b/dev-libs/libconfig/libconfig-1.7.2.ebuild
new file mode 100644
index 000000000000..a426558e586c
--- /dev/null
+++ b/dev-libs/libconfig/libconfig-1.7.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils multilib-minimal
+
+DESCRIPTION="Libconfig is a simple library for manipulating structured configuration files"
+HOMEPAGE="
+	http://www.hyperrealm.com/libconfig/libconfig.html
+	https://github.com/hyperrealm/libconfig
+"
+SRC_URI="https://github.com/hyperrealm/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/11"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-linux"
+IUSE="+cxx static-libs"
+
+DEPEND="
+	sys-devel/libtool
+	sys-devel/bison
+"
+
+src_prepare() {
+	default
+	sed -i \
+		-e '/sleep 3/d' \
+		-e 's|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|g' \
+		configure.ac || die
+	eautoreconf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	econf \
+		$(use_enable cxx) \
+		$(use_enable static-libs static) \
+		--disable-examples
+}
+
+multilib_src_test() {
+	# It responds to check but that does not work as intended
+	emake test
+}
+
+multilib_src_install() {
+	default
+
+	prune_libtool_files
+}