dev-libs/libusb: revbump to fix static-libs bug #515204 for stable users

Package-Manager: portage-2.2.27
RepoMan-Options: --force

1 files changed, 71 insertions, 0 deletions

diff --git a/dev-libs/libusb/libusb-1.0.19-r1.ebuild b/dev-libs/libusb/libusb-1.0.19-r1.ebuild
new file mode 100644
index 000000000000..b16d9a335107
--- /dev/null
+++ b/dev-libs/libusb/libusb-1.0.19-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils toolchain-funcs multilib-minimal
+
+DESCRIPTION="Userspace access to USB devices"
+HOMEPAGE="http://libusb.info/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="1"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 -x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="debug doc examples static-libs test udev"
+
+RDEPEND="udev? ( >=virtual/libudev-208:=[${MULTILIB_USEDEP},static-libs?] )
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-baselibs-20130224-r7
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+	)"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	!udev? ( virtual/os-headers )"
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable udev) \
+		$(use_enable debug debug-log) \
+		$(use_enable test tests-build)
+}
+
+multilib_src_compile() {
+	emake
+
+	if multilib_is_native_abi; then
+		use doc && emake -C doc docs
+	fi
+}
+
+multilib_src_test() {
+	emake check
+
+	# noinst_PROGRAMS from tests/Makefile.am
+	tests/stress || die
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	if multilib_is_native_abi; then
+		gen_usr_ldscript -a usb-1.0
+
+		use doc && dohtml doc/html/*
+	fi
+}
+
+multilib_src_install_all() {
+	prune_libtool_files
+
+	dodoc AUTHORS ChangeLog NEWS PORTING README TODO
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.{c,h}
+		insinto /usr/share/doc/${PF}/examples/getopt
+		doins examples/getopt/*.{c,h}
+	fi
+}