dev-lisp/clozurecl: Gentoo Prefix support

Closes: https://github.com/gentoo/gentoo/pull/4657

Package-Manager: Portage-2.3.5, Repoman-2.3.1

2 files changed, 103 insertions, 0 deletions

diff --git a/dev-lisp/clozurecl/Manifest b/dev-lisp/clozurecl/Manifest
index eec817ea4867..e93322e65517 100644
--- a/dev-lisp/clozurecl/Manifest
+++ b/dev-lisp/clozurecl/Manifest
@@ -1,3 +1,6 @@
 DIST ccl-1.10-linuxx86.tar.gz 43796090 SHA256 8ca272656214837b57746b9b84395987bc524329b38a1f42a605f45bf0282657 SHA512 10504e2569a99ba8b6fc4ac745312435c6be646c86ec3916a3750f823f79b3b8ec87fe53ba2410151feeaaed0609e1760ee3d37a77f01d815d1ec13c2394258e WHIRLPOOL 75c7516eba92ad0fc603301e958dc5ba8271b0819ab46af7f61e97edeb405098c4d84a8f8e8ed73ee85462b6ab7c4805bbcbf0a0f354fb62f077cf8cf10bffa4
+DIST ccl-1.11-darwinx86.tar.gz 14270464 SHA256 cf488651315638246ecdb9b7e8d58d78e0ce3222318044a115533e9b536fd94e SHA512 c2d320872c402405d2972898c77401b1c046685af95e75e0646be989fe91d2ff458a29eaa9c1475cb73531f30858c57a075a23bdf95b9bbf269d63399aea9ea1 WHIRLPOOL 9435cc26c854cd1044178c26e1f6836d4edbfd1763dfc6216017d892c999d8d46ca969c94bb3e7f3503cfad2edfc588ae45716c1c9c5fcd283669110633f45db
+DIST ccl-1.11-linuxarm.tar.gz 23044178 SHA256 64a1911fbe516b73964b377df360c3a40695c6155e0730a6590c67f1953a88f4 SHA512 b8034569f0c47106107fee6bd859051052d43c3bcd625a1956eae467ef0225425d5429678e3584136adc929ccfbbe4b800bffa66ea758cd2b734aa3ed55a9dda WHIRLPOOL bdd4e01fbfb1a5e2ac8b1d2ba9b85dd5e01e94ea0b99718e757b1e1c0b1c5dbc6ffd988ca5d7a7ac494b8cdb8ff4ca36260d61a32e39b6314fc4aec3253f9ff7
 DIST ccl-1.11-linuxx86.tar.gz 42482877 SHA256 08e885e8c2bb6e4abd42b8e8e2b60f257c6929eb34b8ec87ca1ecf848fac6d70 SHA512 34008654fd3ceca55a33413a768c398395141e26b9ea09204739ca7e998fdbe94ab92507eda14cf9bcbb9f76e6c3cae3006d7f2c9f48749c66e1f1281febb409 WHIRLPOOL 4a0d1e6495be62f04f48d6923f95468ca1d1c8bafb3c00d4a5b1f705eb70fac52b7d8ed3b248b698707cd89f1eb4a0196b94d869e9bea52ea895fb8fae00bb41
+DIST ccl-1.11-solarisx86.tar.gz 46926817 SHA256 8b983ec3968e987bae6109dbb12d912ea8f050983dcd3eb9e8a5e91f45f683aa SHA512 f35df9e9c7644331a0f6b77e7b0a6f0b2e297f6249ef7a669932ab6685ca426f87423faf01c64cc1f7eb7fcd0dd4fb7c0d70d039bbcadca5d9201b0a348a36be WHIRLPOOL 11e37a489cf51bff1084cacb33c91aa952f3552b2dac0d23c744d5371f45b8bd41fdb39bfdb5fc40bfc2f2467e5aa6224067f8b8a0ecf01ad9eddbc0d3fded7b
 DIST ccl.html 962003 SHA256 10fe7bf2818a2a029dcd53b274124f84713bed32b24170d09134feee470a5c6e SHA512 0cb9ee8f7eb6007e08241a0797519ff3bfc3d3adc0b5ac86e6a2e9e8b2e316fc421bea3b04159decc0a2b37ff7098147e25266946cc3c1ac367b93e4821a8b64 WHIRLPOOL ce93bb1537fd5c03050b5aa7f14414188a3cacf881ff0fcb87c532a43e51bd6139a11dd58c28397e7981ab120ce85e8303762c5f418f995b1c545f436b4d6abe
diff --git a/dev-lisp/clozurecl/clozurecl-1.11-r2.ebuild b/dev-lisp/clozurecl/clozurecl-1.11-r2.ebuild
new file mode 100644
index 000000000000..8c1c342d8706
--- /dev/null
+++ b/dev-lisp/clozurecl/clozurecl-1.11-r2.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic multilib toolchain-funcs
+
+MY_PN=ccl
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Common Lisp implementation, derived from Digitool's MCL product"
+HOMEPAGE="https://ccl.clozure.com"
+SRC_URI="
+	x86?   ( ${HOMEPAGE}/ftp/pub/release/${PV}/${MY_P}-linuxx86.tar.gz )
+	amd64? ( ${HOMEPAGE}/ftp/pub/release/${PV}/${MY_P}-linuxx86.tar.gz )
+	arm? ( ${HOMEPAGE}/ftp/pub/release/${PV}/${MY_P}-linuxarm.tar.gz )
+	x86-macos? ( ${HOMEPAGE}/ftp/pub/release/${PV}/${MY_P}-darwinx86.tar.gz )
+	x64-macos? ( ${HOMEPAGE}/ftp/pub/release/${PV}/${MY_P}-darwinx86.tar.gz )
+	x86-solaris? ( ${HOMEPAGE}/ftp/pub/release/${PV}/${MY_P}-solarisx86.tar.gz )
+	x64-solaris? ( ${HOMEPAGE}/ftp/pub/release/${PV}/${MY_P}-solarisx86.tar.gz )
+	doc? ( ${HOMEPAGE}/docs/ccl.html )"
+
+LICENSE="LLGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="doc"
+
+RDEPEND=">=dev-lisp/asdf-2.33-r3:="
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}"/${MY_PN}
+ENVD="${T}/50ccl"
+
+src_configure() {
+	if use x86-macos; then
+		CCL_RUNTIME=dx86cl; CCL_HEADERS=darwin-x86-headers; CCL_KERNEL=darwinx8632
+	elif use x64-macos; then
+		CCL_RUNTIME=dx86cl64; CCL_HEADERS=darwin-x86-headers64; CCL_KERNEL=darwinx8664
+	elif use x86-solaris; then
+		CCL_RUNTIME=sx86cl; CCL_HEADERS=solarisx86-headers; CCL_KERNEL=solarisx86
+	elif use x64-solaris; then
+		CCL_RUNTIME=sx86cl64; CCL_HEADERS=solarisx64-headers; CCL_KERNEL=solarisx64
+	elif use x86; then
+		CCL_RUNTIME=lx86cl; CCL_HEADERS=x86-headers; CCL_KERNEL=linuxx8632
+	elif use amd64; then
+		CCL_RUNTIME=lx86cl64; CCL_HEADERS=x86-headers64; CCL_KERNEL=linuxx8664
+	elif use arm; then
+		CCL_RUNTIME=armcl; CCL_HEADERS=arm-headers; CCL_KERNEL=linuxarm
+	elif use ppc; then
+		CCL_RUNTIME=ppccl; CCL_HEADERS=headers; CCL_KERNEL=linuxppc
+	elif use ppc64; then
+		CCL_RUNTIME=ppccl64; CCL_HEADERS=headers64; CCL_KERNEL=linuxppc64
+	fi
+}
+
+src_prepare() {
+	default
+	eapply "${FILESDIR}/${MY_PN}-format.patch"
+	# https://lists.clozure.com/pipermail/openmcl-devel/2016-September/011399.html
+	sed -i "s/-dynamic/-no_pie/" "${S}/lisp-kernel/darwinx8664/Makefile" || die
+	cp "${EPREFIX}/usr/share/common-lisp/source/asdf/build/asdf.lisp" tools/ || die
+}
+
+src_compile() {
+	emake -C lisp-kernel/${CCL_KERNEL} clean
+	emake -C lisp-kernel/${CCL_KERNEL} all CC="$(tc-getCC)"
+
+	unset CCL_DEFAULT_DIRECTORY
+	./${CCL_RUNTIME} -n -b -Q -e '(ccl:rebuild-ccl :full t)' -e '(ccl:quit)' || die "Compilation failed"
+
+	# remove non-owner write permissions on the full-image
+	chmod go-w ${CCL_RUNTIME}{,.image} || die
+
+	esvn_clean
+}
+
+src_install() {
+	local target_dir="/usr/$(get_libdir)/${PN}"
+	local prefix_dir="${EPREFIX}/${target_dir#/}"
+
+	mkdir -p "${D}/${prefix_dir#/}"
+
+	find . -type f -name '*fsl' -delete || die
+	rm -f lisp-kernel/${CCL_KERNEL}/*.o || die
+	cp -a compiler contrib level-0 level-1 lib library lisp-kernel scripts \
+		tools xdump ${CCL_HEADERS} ${CCL_RUNTIME} ${CCL_RUNTIME}.image \
+		"${D}/${prefix_dir#/}" || die
+
+	echo "CCL_DEFAULT_DIRECTORY=${prefix_dir}" > "${ENVD}"
+	doenvd "${ENVD}"
+
+	dosym "${target_dir}/${CCL_RUNTIME}" /usr/bin/ccl
+	dodoc doc/release-notes.txt
+
+	if use doc ; then
+		dodoc "${DISTDIR}/ccl.html"
+		dodoc -r doc/manual
+		dodoc -r examples
+	fi
+}