dev-lua/lua-argparse: migrate to lua eclass

Closes: https://bugs.gentoo.org/752924
Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/dev-lua/lua-argparse/lua-argparse-0.6.0-r100.ebuild b/dev-lua/lua-argparse/lua-argparse-0.6.0-r100.ebuild
new file mode 100644
index 000000000000..ea350b4d10e5
--- /dev/null
+++ b/dev-lua/lua-argparse/lua-argparse-0.6.0-r100.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="Command line argument parser for the Lua Programming Language"
+HOMEPAGE="https://github.com/mpeterv/argparse"
+SRC_URI="https://github.com/mpeterv/${PN/lua-/}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN//lua-/}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="doc test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="${LUA_DEPS}"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( dev-python/sphinx )
+	test? (
+		>=dev-lua/busted-2.0.0-r100[${LUA_USEDEP}]
+		${RDEPEND}
+	)
+"
+
+src_compile() {
+	if use doc; then
+		sphinx-build docsrc html || die
+		rm -rf "${S}"/html/{.doctrees,_sources} || die
+	fi
+}
+
+lua_src_test() {
+	busted  --exclude-tags="unsafe" --lua=${ELUA} || die
+}
+
+src_test() {
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_install() {
+	insinto "$(lua_get_lmod_dir)"
+	doins src/argparse.lua
+}
+
+src_install() {
+	default
+
+	use doc && local -a HTML_DOCS=( "html/." )
+	einstalldocs
+
+	lua_foreach_impl lua_src_install
+}
diff --git a/dev-lua/lua-argparse/metadata.xml b/dev-lua/lua-argparse/metadata.xml
index 3af620136775..5ec193fa4b31 100644
--- a/dev-lua/lua-argparse/metadata.xml
+++ b/dev-lua/lua-argparse/metadata.xml
@@ -2,6 +2,10 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 	<maintainer type="person">
+		<email>conikost@gmail.com</email>
+		<name>Conrad Kostecki</name>
+	</maintainer>
+	<maintainer type="person">
 		<email>vpayno+gentoo@gmail.com</email>
 		<name>Victor Payno</name>
 	</maintainer>