dev-ml/core_extended: bump to 113.33.00

Package-Manager: portage-2.2.28
Signed-off-by: Alexis Ballier <aballier@gentoo.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-ml/core_extended/core_extended-113.33.00.ebuild b/dev-ml/core_extended/core_extended-113.33.00.ebuild
new file mode 100644
index 000000000000..9f39cce7f904
--- /dev/null
+++ b/dev-ml/core_extended/core_extended-113.33.00.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+OASIS_BUILD_DOCS=1
+OASIS_BUILD_TESTS=1
+
+inherit oasis
+
+DESCRIPTION="Jane Street's alternative to the standard library"
+HOMEPAGE="http://www.janestreet.com/ocaml"
+SRC_URI="http://ocaml.janestreet.com/ocaml-core/${PV%.*}/files/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE=""
+
+RDEPEND="
+	>=dev-ml/core-113.24:=
+	>=dev-ml/bin-prot-113.24:=
+	>=dev-ml/fieldslib-113.24:=
+	dev-ml/ppx_assert:=
+	dev-ml/ppx_bench:=
+	dev-ml/ppx_driver:=
+	dev-ml/ppx_expect:=
+	dev-ml/ppx_inline_test:=
+	dev-ml/ppx_jane:=
+	dev-ml/re2:=
+	>=dev-ml/sexplib-113.24:=
+	dev-ml/textutils:=
+	dev-ml/typerep:=
+	dev-ml/variantslib:=
+	"
+DEPEND="${RDEPEND} dev-ml/opam"
+
+src_configure() {
+	emake setup.exe
+	OASIS_SETUP_COMMAND="./setup.exe" oasis_src_configure
+}
+
+src_compile() {
+	emake
+}
+
+src_install() {
+	opam-installer -i \
+		--prefix="${ED}/usr" \
+		--libdir="${D}/$(ocamlc -where)" \
+		--docdir="${ED}/usr/share/doc/${PF}" \
+		${PN}.install || die
+	dodoc CHANGES.md
+}