dev-python/apptools: Version Bump

Package-Manager: portage-2.2.22
Signed-off-by: Justin Lecher <jlec@gentoo.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/apptools/apptools-4.3.0.ebuild b/dev-python/apptools/apptools-4.3.0.ebuild
new file mode 100644
index 000000000000..e54896cb6582
--- /dev/null
+++ b/dev-python/apptools/apptools-4.3.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Enthought Tool Suite: Application tools"
+HOMEPAGE="http://code.enthought.com/projects/app_tools/ https://pypi.python.org/pypi/apptools"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RDEPEND="
+	dev-python/configobj[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/traitsui[${PYTHON_USEDEP}]
+	>=dev-python/traits-4[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		>=dev-python/pyface-4[${PYTHON_USEDEP}]
+		media-fonts/font-cursor-misc
+		media-fonts/font-misc-misc
+		sci-visualization/mayavi[${PYTHON_USEDEP}]
+		dev-python/traits[${PYTHON_USEDEP}]
+		dev-python/traitsui[${PYTHON_USEDEP}]
+	)"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	# Ignore test file that imports a long deprecated module of traits
+	VIRTUALX_COMMAND="nosetests -I test_state_pickler.py" virtualmake
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}