dev-python/carbon-1.1.7: version bump, drop x64-solaris

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Fabian Groffen <grobian@gentoo.org>

2 files changed, 63 insertions, 0 deletions

diff --git a/dev-python/carbon/Manifest b/dev-python/carbon/Manifest
index 02d3976e9e4e..92a1ce5dd238 100644
--- a/dev-python/carbon/Manifest
+++ b/dev-python/carbon/Manifest
@@ -1 +1,2 @@
 DIST carbon-1.1.5.tar.gz 72365 BLAKE2B 304e515fd3cae806e141d0a76983d13967885a7e57c310d86c0c83560aa306a573676fb0135fceccf14cc7ed42d8a9dcb7869ab0d6ac3b2fc00c2fb088011873 SHA512 1b3a0a0d4005e2ec8d5bca062b41f0e18329c1bc4d3a4b3eca5e8f7c94c20387281392eefceaca90294e51860eabecca242c487068433119f1f249f8659ed560
+DIST carbon-1.1.7.tar.gz 73380 BLAKE2B 8f9c807bc5e1c6fc020ae31179b6c0c11724b1110def323f92e158c5cf7c88291686bdc7f9078fb9234e5f2877fd745f7ec581533fa9a77e0307bf56f8ba60e0 SHA512 f0c5c64fa02cfd5940a7b23dbb3f2af27f67595e301ae719f4e2e9cdb48d4a5673d36a60adc8d338a55202f8e89873a7539c960cc16649903305191c6b0fc875
diff --git a/dev-python/carbon/carbon-1.1.7.ebuild b/dev-python/carbon/carbon-1.1.7.ebuild
new file mode 100644
index 000000000000..906b0342f044
--- /dev/null
+++ b/dev-python/carbon/carbon-1.1.7.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1
+
+DESCRIPTION="Backend data caching and persistence daemon for Graphite"
+HOMEPAGE="https://graphiteapp.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="Apache-2.0"
+KEYWORDS="~amd64 ~x86"
+
+# whisper appears to have been missed from listing in install_requires in setup.py
+RDEPEND="
+	dev-python/twisted[${PYTHON_USEDEP}]
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	=dev-python/whisper-${PV}*[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	# Do not install the configuration and data files. We install them
+	# somewhere sensible by hand.
+	sed -i -e '/data_files=install_files,/d' setup.py || die
+	# We want FHS-style paths instead of /opt/graphite
+	export GRAPHITE_NO_PREFIX=yes
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /etc/carbon
+	doins conf/*
+
+	keepdir /var/log/carbon /var/lib/carbon/{whisper,lists,rrd}
+
+	newinitd "${FILESDIR}"/carbon.initd2 carbon-cache
+	newinitd "${FILESDIR}"/carbon.initd2 carbon-relay
+	newinitd "${FILESDIR}"/carbon.initd2 carbon-aggregator
+
+	newconfd "${FILESDIR}"/carbon.confd carbon-cache
+	newconfd "${FILESDIR}"/carbon.confd carbon-relay
+	newconfd "${FILESDIR}"/carbon.confd carbon-aggregator
+}
+
+pkg_postinst() {
+	einfo 'This ebuild installs carbon into FHS-style paths.'
+	einfo 'You will probably have to set GRAPHITE_CONF_DIR to /etc/carbon'
+	einfo 'and GRAPHITE_STORAGE_DIR to /var/lib/carbon to make use of this'
+	einfo '(see /etc/carbon/carbon.conf.example).'
+	einfo ' '
+	einfo 'OpenRC init script supports multiple instances !'
+	einfo 'Example to run an instance b of carbon-cache :'
+	einfo '    ln -s /etc/init.d/carbon-cache /etc/init.d/carbon-cache.b'
+	einfo '    cp /etc/conf.d/carbon-cache /etc/conf.d/carbon-cache.b'
+}