dev-python/cython: Bump to 0.29.15

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 81 insertions, 0 deletions

diff --git a/dev-python/cython/Manifest b/dev-python/cython/Manifest
index 69e66c905697..79571bf9a7d6 100644
--- a/dev-python/cython/Manifest
+++ b/dev-python/cython/Manifest
@@ -2,3 +2,4 @@ DIST Cython-0.29.12.tar.gz 2050537 BLAKE2B 86c5ffd07e97d549f2d98ae0aa66a03dc2f8e
 DIST Cython-0.29.4.tar.gz 2044382 BLAKE2B b36d27706a3270805f66190a4cf2735eaf20b1b932365b324a433c0e58e63e860ce1500333233c3539ae697886ac0adc361a2c158d5d064a3ea05843debc3f26 SHA512 8f115e36975aaf64eda4df8b0a85378d0c80b3292dbd162be826b939def03bdc9f3eb937676e2367003c2944b570d97f50d7880becfdb2fdc5144077b4a722dc
 DIST cython-0.29.13.gh.tar.gz 2072564 BLAKE2B 55a8c5c932262972cfa55ee2771e17ab5a57beab03d0dac5668f654a0bf68850ef62b7e59b322c527115af48b7243b9c919e739eaf440338a50b89c4645c0fbf SHA512 79efebfddabf31a046ae86a2c2170e0956098f4b1c7b8bbd338d30be7c96c31ee2d648332fc16ad9cf1e5d0ea4ca1a070b2d31ccbeae0c0f86a2f7700b92f656
 DIST cython-0.29.14.gh.tar.gz 2075030 BLAKE2B 12bbc2979c34fee9b498f5425d2cea5cedebda474e3f4ee6c9eb3185a4e33fc84df6c16454830316548e36cd9fb7c47f0925b0d6e16b325cbd81f8747c7e492a SHA512 fa1575fc5ec7ee19de34f91a15bdd45d889f54217dbe2a9654604ada90d8d86fe7bceb86449c41b68d6b65459769916a0d7d5f5da21c5597aedc876cde4e37df
+DIST cython-0.29.15.gh.tar.gz 2075879 BLAKE2B e6322656c819c6b09e235c32d2b520e8fe917c864047d028dd67041e70251025f14accbd76499b7b9290d0424989adf89321f251526e66a892bdc243ba80ba7f SHA512 bd0872359d31a41750353bb0d7f03c2a40aa2bf6e492148e693321cef15b02ae4f8d5f5a00efde7216f09a6ac06f2bb3ded9d00e27ad0cfc53605f3a9ef55af8
diff --git a/dev-python/cython/cython-0.29.15.ebuild b/dev-python/cython/cython-0.29.15.ebuild
new file mode 100644
index 000000000000..460ca46f183f
--- /dev/null
+++ b/dev-python/cython/cython-0.29.15.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{6,7,8} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 toolchain-funcs elisp-common
+
+DESCRIPTION="A Python to C compiler"
+HOMEPAGE="https://cython.org https://pypi.org/project/Cython/
+	https://github.com/cython/cython"
+SRC_URI="https://github.com/cython/cython/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="emacs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	emacs? ( >=app-editors/emacs-23.1:* )
+"
+BDEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep 'dev-python/numpy[${PYTHON_USEDEP}]' \
+			'python3*')
+	)"
+
+PATCHES=(
+	"${FILESDIR}/cython-0.29.14-sphinx-update.patch"
+)
+
+SITEFILE=50cython-gentoo.el
+
+distutils_enable_sphinx docs
+
+python_compile() {
+	if ! python_is_python3; then
+		local CFLAGS="${CFLAGS} -fno-strict-aliasing"
+		local CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+	fi
+
+	# Python gets confused when it is in sys.path before build.
+	local -x PYTHONPATH=
+
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	use emacs && elisp-compile Tools/cython-mode.el
+}
+
+python_test() {
+	tc-export CC
+	# https://github.com/cython/cython/issues/1911
+	local -x CFLAGS="${CFLAGS} -fno-strict-overflow"
+	"${PYTHON}" runtests.py -vv --work-dir "${BUILD_DIR}"/tests \
+		|| die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( CHANGES.rst README.rst ToDo.txt USAGE.txt )
+	distutils-r1_python_install_all
+
+	if use emacs; then
+		elisp-install ${PN} Tools/cython-mode.*
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}