dev-python/mako: bump to 1.0.7, add PyPy3

* Tests now pass with pypy.
* Fix mock DEPEND to include pypy.
* Don't add RDEPEND to DEPND unconditionally.
* Drop postinst message related to a version that was released in 2012.
* Use pytest instead of nose (like upstream).

Closes: https://bugs.gentoo.org/620906
Package-Manager: Portage-2.3.42, Repoman-2.3.9

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-python/mako/mako-1.0.7.ebuild b/dev-python/mako/mako-1.0.7.ebuild
new file mode 100644
index 000000000000..0a1c1dab8219
--- /dev/null
+++ b/dev-python/mako/mako-1.0.7.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1 eutils
+
+MY_PN="Mako"
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="A Python templating language"
+HOMEPAGE="http://www.makotemplates.org/ https://pypi.org/project/Mako/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' pypy python2_7)
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_P}"
+
+python_test() {
+	py.test -v || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	rm -r doc/build || die
+
+	use doc && local HTML_DOCS=( doc/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	elog "Optional dependencies:"
+	optfeature "caching support" dev-python/beaker
+}