dev-python/oslo-sphinx: bup

Package-Manager: portage-2.3.0

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-python/oslo-sphinx/oslo-sphinx-4.7.0.ebuild b/dev-python/oslo-sphinx/oslo-sphinx-4.7.0.ebuild
new file mode 100644
index 000000000000..cf9727682f36
--- /dev/null
+++ b/dev-python/oslo-sphinx/oslo-sphinx-4.7.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5}} )
+
+inherit distutils-r1
+
+MY_PN="${PN//-/}"
+
+DESCRIPTION="OpenStack Sphinx Extensions and Theme"
+HOMEPAGE="http://www.openstack.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="doc"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/pbr-1.6[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/sphinx-1.2.1[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	>=dev-python/requests-2.10.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+
+	distutils-r1_python_install_all
+}