dev-python/parse_type: add 0.5.6

Use github given pypi is stuck at 0.5.2

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 40 insertions, 0 deletions

diff --git a/dev-python/parse_type/parse_type-0.5.6.ebuild b/dev-python/parse_type/parse_type-0.5.6.ebuild
new file mode 100644
index 000000000000..dc269e3e675f
--- /dev/null
+++ b/dev-python/parse_type/parse_type-0.5.6.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Extension to the parse module"
+HOMEPAGE="https://pypi.org/project/parse-type/"
+SRC_URI="https://github.com/jenisys/parse_type/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/parse[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.5.2-setupwarn.patch
+)
+
+DOCS=( CHANGES.txt README.rst )
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# disable unnecessary html test report and its pytest-html dependency
+	sed -i '/^addopts/,/report.xml$/d' pytest.ini || die
+}
+
+python_compile() {
+	2to3 -nw --no-diffs ${PN} tests || die
+
+	distutils-r1_python_compile
+}