dev-python/pydispatcher: Switch to PyPyDispatcher fork

Closes: https://bugs.gentoo.org/626680

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-python/pydispatcher/pydispatcher-2.1.2.ebuild b/dev-python/pydispatcher/pydispatcher-2.1.2.ebuild
new file mode 100644
index 000000000000..f5b1510f8dae
--- /dev/null
+++ b/dev-python/pydispatcher/pydispatcher-2.1.2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+MY_P="PyPyDispatcher-${PV}"
+DESCRIPTION="Multi-producer-multi-consumer signal dispatching mechanism"
+HOMEPAGE="https://github.com/scrapy/pypydispatcher https://pypi.python.org/pypi/PyPyDispatcher"
+SRC_URI="mirror://pypi/${MY_P::1}/${MY_P%-*}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~x86"
+IUSE="doc"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+RDEPEND=""
+
+S=${WORKDIR}/${MY_P}
+
+python_compile_all() {
+	if use doc; then
+		cd docs/pydoc || die
+		"${EPYTHON}" builddocs.py || die
+	fi
+}
+
+python_test() {
+	"${EPYTHON}" -m unittest discover -v || die "Tests fail for ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/pydoc/. )
+	distutils-r1_python_install_all
+}