dev-python/rapidfuzz: Bump to 2.13.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-python/rapidfuzz/rapidfuzz-2.13.3.ebuild b/dev-python/rapidfuzz/rapidfuzz-2.13.3.ebuild
new file mode 100644
index 000000000000..f2d8defdd62d
--- /dev/null
+++ b/dev-python/rapidfuzz/rapidfuzz-2.13.3.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# custom wrapper over setuptools
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Rapid fuzzy string matching in Python using various string metrics"
+HOMEPAGE="
+	https://github.com/maxbachmann/RapidFuzz/
+	https://pypi.org/project/rapidfuzz/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+# all these are header-only libraries
+DEPEND="
+	>=dev-cpp/taskflow-3.0.0
+	>=dev-cpp/rapidfuzz-cpp-1.10.0
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/rapidfuzz_capi[${PYTHON_USEDEP}]
+	>=dev-python/scikit-build-0.16.2[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# sterilize build flags
+	sed -i -e '/CMAKE_INTERPROCEDURAL_OPTIMIZATION/d' CMakeLists.txt || die
+
+	distutils-r1_src_prepare
+
+	export RAPIDFUZZ_BUILD_EXTENSION=1
+}