dev-python/setuptools: Bump to 56.2.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 77 insertions, 0 deletions

diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index 17917de93786..062a0965e70b 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -2,3 +2,4 @@ DIST setuptools-53.1.0.tar.gz 2051159 BLAKE2B f4148df45f5c62acd6acae833619dcae50
 DIST setuptools-54.2.0.tar.gz 2054279 BLAKE2B 2a52e76808fb2bc6df4c59ac7476a9386401180ff6c0d52a5f3d87aedf976a3057cfa0a7ddf2a4497c4c1552d5ebe4810c4bbfa127e1293f950054bddbf7d835 SHA512 b18cd075cf59b8648611eef1874de41199ede6ffe6d7f5047586c6ac8783fe18b9a4f537783e590e7aec127033f612b93925e92f039bd6416a609fcfb262e354
 DIST setuptools-56.0.0.tar.gz 2054762 BLAKE2B 3fc0f47304109f765ff0f8430dae735005d508aaa79609c5ca08217eb3802014267bd0f1a4f4678b417143f0d22b4b27f166573e41685229e0d4491b1789713d SHA512 951d43a0192b9dddacd7bd7ff6b76e281c14071771096db3c413fde6ea67b0c534f17a770cb3464cd3a6a4e8145b82f4cf5c0228e76e6f2cefe88d33748816e9
 DIST setuptools-56.1.0.tar.gz 2109659 BLAKE2B 2538391c7ee135f12550da9bb7c110aedcc1480616260195f3f8fc8b8a650651f5bb1f0244832801f897381a8663fc88e2b3840101c560595844af5b192259a2 SHA512 e490c61b4453678339ed3222b4ff39f218fdf515f6de0079b7e4343bf2e1a74a0c8d2f2c9108f462986cf06bc940f260bce29c3f61cc9e0c88471914de345ef1
+DIST setuptools-56.2.0.tar.gz 2110133 BLAKE2B 90c75ba006becc9f564eecd7d46a9ce70c9ad17eacf2e17b3551116b962e08af0084919fccc18ec29a54b98e8fe2419d129554a7b38fdd1104f472fb2e6f9995 SHA512 858d46909335ff0b0441d5860788803100a8fe9f5a1d1f17353bf961bc77191c3237501c1838fdb6ec8e4b2c66874ffd4e8342b42cc2673cb866706660704ea6
diff --git a/dev-python/setuptools/setuptools-56.2.0.ebuild b/dev-python/setuptools/setuptools-56.2.0.ebuild
new file mode 100644
index 000000000000..d47acafe9ddc
--- /dev/null
+++ b/dev-python/setuptools/setuptools-56.2.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+# Set to 'manual' to avoid triggering install QA check
+DISTUTILS_USE_SETUPTOOLS=manual
+PYTHON_COMPAT=( python3_{7..10} pypy3 )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="https://github.com/pypa/setuptools https://pypi.org/project/setuptools/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/jaraco-envs[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+		' python3_{7..9} pypy3)
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	' python3_{7..9} pypy3)"
+
+# Force in-source build because build system modifies sources.
+DISTUTILS_IN_SOURCE_BUILD=1
+
+DOCS=( {CHANGES,README}.rst )
+
+python_test() {
+	# temporarily skipped, until we port all test deps
+	[[ ${EPYTHON} == python3.10 ]] && continue
+
+	distutils_install_for_testing --via-root
+	local deselect=(
+		# network
+		'setuptools/tests/test_virtualenv.py::test_pip_upgrade_from_source[None]'
+		setuptools/tests/test_distutils_adoption.py
+		# TODO
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+	)
+	[[ ${EPYTHON} == pypy3 ]] && deselect+=(
+		setuptools/tests/test_develop.py::TestDevelop::test_2to3_user_mode
+	)
+
+	# test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
+	# It tries to sandbox the test in a tempdir
+	HOME="${PWD}" epytest ${deselect[@]/#/--deselect } \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" \
+		setuptools
+}
+
+python_install() {
+	export DISTRIBUTE_DISABLE_VERSIONED_EASY_INSTALL_SCRIPT=1
+	distutils-r1_python_install
+}