dev-python/setuptools: Bump to 57.0.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 77 insertions, 0 deletions

diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index 77c75b9a0727..710d84b85fb2 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -1,2 +1,3 @@
 DIST setuptools-56.0.0.tar.gz 2054762 BLAKE2B 3fc0f47304109f765ff0f8430dae735005d508aaa79609c5ca08217eb3802014267bd0f1a4f4678b417143f0d22b4b27f166573e41685229e0d4491b1789713d SHA512 951d43a0192b9dddacd7bd7ff6b76e281c14071771096db3c413fde6ea67b0c534f17a770cb3464cd3a6a4e8145b82f4cf5c0228e76e6f2cefe88d33748816e9
 DIST setuptools-56.2.0.tar.gz 2110133 BLAKE2B 90c75ba006becc9f564eecd7d46a9ce70c9ad17eacf2e17b3551116b962e08af0084919fccc18ec29a54b98e8fe2419d129554a7b38fdd1104f472fb2e6f9995 SHA512 858d46909335ff0b0441d5860788803100a8fe9f5a1d1f17353bf961bc77191c3237501c1838fdb6ec8e4b2c66874ffd4e8342b42cc2673cb866706660704ea6
+DIST setuptools-57.0.0.tar.gz 2144749 BLAKE2B e1fc99503ee5de425b70bf2733b1c489693e38cd256bf95cb321671bdaf87745eaaf40c43bcd03756a4cefa408dd1414f8c30af274963e3a0ae57f7b95d3f9c0 SHA512 5277d8630367d6b16a49e36ed84d8cc6abfaedf87dac3f795b204626a8f15ca9fd80d158a465d8bcabe9c074c76b87c3378d82a4ba5feee1ac6a5f2c91db061e
diff --git a/dev-python/setuptools/setuptools-57.0.0.ebuild b/dev-python/setuptools/setuptools-57.0.0.ebuild
new file mode 100644
index 000000000000..77c8325733a5
--- /dev/null
+++ b/dev-python/setuptools/setuptools-57.0.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+# Set to 'manual' to avoid triggering install QA check
+DISTUTILS_USE_SETUPTOOLS=manual
+PYTHON_COMPAT=( python3_{7..10} pypy3 )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="https://github.com/pypa/setuptools https://pypi.org/project/setuptools/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/jaraco-envs[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+		' python3_{7..9} pypy3)
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	' python3_{7..9} pypy3)"
+
+# Force in-source build because build system modifies sources.
+DISTUTILS_IN_SOURCE_BUILD=1
+
+DOCS=( {CHANGES,README}.rst )
+
+python_test() {
+	# temporarily skipped, until we port all test deps
+	[[ ${EPYTHON} == python3.10 ]] && continue
+
+	distutils_install_for_testing --via-root
+	local deselect=(
+		# network
+		'setuptools/tests/test_virtualenv.py::test_pip_upgrade_from_source[None]'
+		setuptools/tests/test_distutils_adoption.py
+		# TODO
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+	)
+	[[ ${EPYTHON} == pypy3 ]] && deselect+=(
+		setuptools/tests/test_develop.py::TestDevelop::test_2to3_user_mode
+	)
+
+	# test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
+	# It tries to sandbox the test in a tempdir
+	HOME="${PWD}" epytest ${deselect[@]/#/--deselect } \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" \
+		setuptools
+}
+
+python_install() {
+	export DISTRIBUTE_DISABLE_VERSIONED_EASY_INSTALL_SCRIPT=1
+	distutils-r1_python_install
+}