dev-python/spyder: add version 5.0.3

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

3 files changed, 218 insertions, 0 deletions

diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index 873f9ac3b06b..61ffdf484231 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -1,5 +1,7 @@
 DIST spyder-4.2.3.tar.gz 11539371 BLAKE2B aecd2e9772c52e644e9c0503195e380fffecdfaa5aea3f00a64e98a969faf3de4e0d8eb0515cc59893f28deb7733403826e90e36006ad7f8f4d67e8ef5e64543 SHA512 9e56efab8862c21e7496d45e813d28c4e9be583275352b0a6e0a58e99f6c0234fa9862da66705839beacb971dde9b6edc253405d9d62853a3c4c9c9991844846
 DIST spyder-4.2.5.tar.gz 11539071 BLAKE2B 9d7a98da018aae934803d640995fe2dfa6bbb20bfc7140bd00f5e7a00a09c47922fefd8df84f4b217a50176ee190515da6f4cbf498a03cae68e2ac4f5ec70664 SHA512 081b047a45b7522a69b1b21a221ab5cdef47f87f36ed4423ff63297d205f924c1627517c50622acb2d10efa094bc506fed4ec88f861775d3f58e81ac6ef017ac
 DIST spyder-5.0.0.tar.gz 19967667 BLAKE2B 072d65949f83e8831a6c88ef5472401f7b6ef305dd193baea34d63ce865d49a1181d0282df2e4c0025ff928e6a0a6c13312fb69f3329343a45def6ee9f30b9d3 SHA512 c76355314c7f623fbcc99540c8ecc4b57c18f9c0551688b1e4016b4510262305837d1637df38f412314fc98abd2c359d834bf380300a46b098503db561f83177
+DIST spyder-5.0.3.tar.gz 20586502 BLAKE2B b8223273b638b57827f17037c47bb7bf53f19978fe9db343e354f557f4da17cfa03a36c013cab68b8b91b66495316a12d9652d864b8b089a495668b667a26b8c SHA512 c9b7c3a6755bc14ae84d8cd2c4166620a6fd1e83c097e2766f9f5190057775e4e3e9ba192d9eeb1cc434be11ac392f767239ae2d98cf40d95ffda4cf7cbeb358
+DIST spyder-docs-588cdf55cceffea7a3f31d98c0720bfe7df34b72.tar.gz 75780347 BLAKE2B c344ee0798e5780bfac5a8483c2992dfdddba5222fdd4a7c5603514bc612cc7300ec0cb49ebdcce6633d0cca8a5a36cfb5a2105c7f91febb5982dc2ea40fb86c SHA512 72f4644e872c57e229da8958a125bf405fa073ff99071b3555d97d8f8f71dc7b9f0dffbe61adf886e6bf3191894c639dd408d8dc76d65bc170bf7578b5b05558
 DIST spyder-docs-5c9c8a3317045c2d301e05b751943be9b521d129.tar.gz 66692311 BLAKE2B ec741a9cd830bc8a5776be1d52dcac9649c8abf33faec0ac8741d95625d8aeda2b8c0d2bdbef02c068a22ec62a4d5281a48e996530e1bd2e6de43b86e0a14ffe SHA512 73bd05ef31f69ebd80bb488017998536c4ed0e63a331efe743d9d858b936df287253f333d09beac6d2b249a96e8f82538d321850a64b0941db3d0141122995eb
 DIST spyder-docs-78b25754c69a20643258821146e398ad5535c920.tar.gz 69167467 BLAKE2B d2815d552002f329b5fac59329fba3b3b0cd592bcbdacc0878966919e44dbab29548533661e60a1b9b8fd763d57d1e4c2f761782ace1b0a814a5f0cec1f66af9 SHA512 10764367fd5f830d7a3620b9d9e7ec4ab74539c1f48326c0c40f7caff74a50401addc7609fe1558c57dac4649d0a214c0d2d77cecd100bd8574151134e49634d
diff --git a/dev-python/spyder/files/spyder-5.0.1-doc-theme-renamed.patch b/dev-python/spyder/files/spyder-5.0.1-doc-theme-renamed.patch
new file mode 100644
index 000000000000..5edf7e854d0b
--- /dev/null
+++ b/dev-python/spyder/files/spyder-5.0.1-doc-theme-renamed.patch
@@ -0,0 +1,13 @@
+diff --git a/doc/conf.py b/doc/conf.py
+index a3dc817..f428860 100644
+--- a/docs/doc/conf.py
++++ b/docs/doc/conf.py
+@@ -143,7 +143,7 @@
+ #
+ # CI = True
+ # TRAVIS_BRANCH = 'master'
+-html_theme = "pandas_sphinx_theme"
++html_theme = "pydata_sphinx_theme"
+ html_logo = '_static/images/spyder_logo.png'
+ html_theme_options = {
+     "external_links": [
diff --git a/dev-python/spyder/spyder-5.0.3.ebuild b/dev-python/spyder/spyder-5.0.3.ebuild
new file mode 100644
index 000000000000..c07dccb427fa
--- /dev/null
+++ b/dev-python/spyder/spyder-5.0.3.ebuild
@@ -0,0 +1,203 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit optfeature xdg distutils-r1
+
+# Commit of documentation to fetch
+DOCS_PV="588cdf55cceffea7a3f31d98c0720bfe7df34b72"
+
+DESCRIPTION="The Scientific Python Development Environment"
+HOMEPAGE="
+	https://www.spyder-ide.org/
+	https://github.com/spyder-ide/spyder/
+	https://pypi.org/project/spyder/
+"
+SRC_URI="
+	https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz ->
+		${PN}-docs-${DOCS_PV}.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# The test suite often hangs or does not work. Technically spyder requires
+# pyqt5<13, which we do not have in ::gentoo any more. Likely this is the reason
+# many of the tests fail or hang. RESTRICTing because IMO it is not worth the
+# several hours I spend every single version bump checking which tests do and
+# do not work. Spyder itself works fine with pyqt5>13.
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/cloudpickle-0.5.0[${PYTHON_USEDEP}]
+	>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
+	>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.6.0[${PYTHON_USEDEP}]
+	~dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
+	>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
+	~dev-python/parso-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/pylint-1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyls-black-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/pyls-spyder-0.3.2[${PYTHON_USEDEP}]
+	<dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/python-language-server-0.36.2[${PYTHON_USEDEP}]
+	<dev-python/python-language-server-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	~dev-python/qdarkstyle-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/qstylizer-0.1.10[${PYTHON_USEDEP}]
+	>=dev-python/qtawesome-1.0.2[${PYTHON_USEDEP}]
+	>=dev-python/qtconsole-5.1.0[${PYTHON_USEDEP}]
+	>=dev-python/QtPy-1.5.0[${PYTHON_USEDEP},svg,webengine]
+	>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
+	>=dev-python/spyder-kernels-2.0.3[${PYTHON_USEDEP}]
+	<dev-python/spyder-kernels-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
+	>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
+	<dev-python/watchdog-2.0.0[${PYTHON_USEDEP}]
+"
+
+# python-language-server[all] deps
+RDEPEND+="
+	dev-python/autopep8[${PYTHON_USEDEP}]
+	>=dev-python/flake8-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
+	<dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/pycodestyle-2.6.0[${PYTHON_USEDEP}]
+	<dev-python/pycodestyle-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyflakes-2.2.0[${PYTHON_USEDEP}]
+	<dev-python/pyflakes-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/rope-0.10.5[${PYTHON_USEDEP}]
+	dev-python/yapf[${PYTHON_USEDEP}]
+"
+
+# currently does not work with pyside2
+RDEPEND+="
+	dev-python/PyQt5[${PYTHON_USEDEP}]
+	dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/matplotlib[tk,${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		<dev-python/pytest-6.0[${PYTHON_USEDEP}]
+		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-ordering[${PYTHON_USEDEP}]
+		dev-python/pytest-qt[${PYTHON_USEDEP}]
+		dev-python/pytest-xvfb[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/sympy[${PYTHON_USEDEP}]
+	)"
+
+# Based on the courtesy of Arfrever
+# This patch removes a call to update-desktop-database during build
+# This fails because access is denied to this command during build
+PATCHES=(
+	"${FILESDIR}/${PN}-5.0.0-build.patch"
+	"${FILESDIR}/${PN}-5.0.1-doc-theme-renamed.patch"
+)
+
+DOCS=(
+	"AUTHORS.txt"
+	"Announcements.md"
+	"CHANGELOG.md"
+	"CODE_OF_CONDUCT.md"
+	"CONTRIBUTING.md"
+	"NOTICE.txt"
+	"README.md"
+	"RELEASE.md"
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/doc \
+	dev-python/sphinx-panels \
+	dev-python/pydata-sphinx-theme \
+	dev-python/sphinx-multiversion
+
+python_prepare_all() {
+	# move docs into workdir
+	mv ../spyder-docs-${DOCS_PV}* docs || die
+
+	# these dependencies are packaged separately:
+	#    dev-python/spyder-kernels,
+	#    dev-python/python-language-server,
+	#    dev-python/qdarkstyle
+	rm -r external-deps/* || die
+	# runs against things packaged in external-deps dir
+	rm conftest.py || die
+
+	# do not depend on pyqt5<13
+	sed -i -e '/pyqt5/d' \
+		-e '/pyqtwebengine/d' \
+			setup.py || die
+
+	# do not check deps, fails because we removed pyqt5 dependency above
+	sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
+		spyder/tests/test_dependencies_in_sync.py || die
+
+	# can't check for update, need network
+	rm spyder/workers/tests/test_update.py || die
+
+	# skip online test
+	rm spyder/widgets/github/tests/test_github_backend.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+# Calling pytest directly makes the tests freeze after completing even if successful
+# Exit code is nonzero even upon success, so can't add || die here test results
+# should be checked for success manually
+python_test() {
+	"${EPYTHON}" runtests.py
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
+	optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
+	optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
+	optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
+	optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
+	optfeature "Run Cython files in the IPython console" dev-python/cython
+	optfeature "The hdf5/h5py plugin" dev-python/h5py
+	optfeature "The line profiler plugin" dev-python/spyder-line-profiler
+	optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
+	# spyder-autopep8 does not have a release (yet)
+	# and are not compatible with >=spyder-4.0.0 at the moment
+	# optfeature "The autopep8 plugin" dev-python/spyder-autopep8
+	optfeature "Vim key bindings" dev-python/spyder-vim
+	optfeature "Unittest support" dev-python/spyder-unittest
+	optfeature "Jupyter notebook support" dev-python/spyder-notebook
+	optfeature "System terminal inside spyder" dev-python/spyder-terminal
+	# spyder-reports not yet updated to >=spyder-4.0.0
+	# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
+	elog
+	elog "Spyder currently only works with PyQt5 as QtPy backend, PySide2 is not supported."
+	elog "Please ensure that 'eselect qtpy' is set to PyQt5."
+}