dev-python/translate-toolkit: 2.0.0 version bump

Gentoo-bug: 608108

Package-Manager: portage-2.3.3

2 files changed, 84 insertions, 0 deletions

diff --git a/dev-python/translate-toolkit/Manifest b/dev-python/translate-toolkit/Manifest
index 996901ff0dd5..0dabf35ce34e 100644
--- a/dev-python/translate-toolkit/Manifest
+++ b/dev-python/translate-toolkit/Manifest
@@ -1,2 +1,3 @@
 DIST translate-toolkit-1.12.0.tar.bz2 5329772 SHA256 11e332f2a29d8644364b4ca79b4ac079df328626ec8c27ac0e8cc454696719ca SHA512 c84424790ad66492dec97a5ec5601f5ffa68d23b219836def998847449b902970ac32fcb7d06455365e00c7b06f49d7dedda5257275bf7e845b16100153922dd WHIRLPOOL 866eb62056a30c8042d96a1ec06a23e56c2a5121dd66234a8b0889193548fff962d4c56700bb50a01c793e2443d49e33a02d92d5b53513f6c7b0805af827decf
+DIST translate-toolkit-2.0.0.tar.gz 1106464 SHA256 aa6c68c786ec82f7bcfc03ac39c4dfe4669a45efc8e2fe24470fe61aaef8c41f SHA512 a349f64438683bb00a7a7ba0537b7c9a268e6222d2df67991eb5d47b05a446a6049bf42918edc97ba8b08a89a42850eb37f6b4b917ccf5c44494885a853ffe1f WHIRLPOOL 52d620c73b7feed483dd32aa8e28493ac7a9b610bafadce4effa58106d07bc8e2e3165e6a512c6c678f7a7fb980c2e69f134a992d55ef2b0f62a42596a0e3e3b
 DIST translate-toolkit-2.0.0_beta7.tar.gz 1099096 SHA256 87f53a10ce9d2d19b5ff8d83a7b2aa03f30c1c9b2fd742db3909fbbd2f4221c0 SHA512 dd8897532f66aca451a578537038c3adac2a3fbe1e7756febc97e2a2a024e4460806a2a28d2e9e66239eba938d02053616d3c683568a032b5c4c5c0629bd8abc WHIRLPOOL 5301becae7728f761ca142c9e417d04da2e558723cb9fa421ee6c558cfb05ea8bce7eb8e5d4360ecaa2f924776b675879c9f3afca4a958330374839deb2a2ee3
diff --git a/dev-python/translate-toolkit/translate-toolkit-2.0.0.ebuild b/dev-python/translate-toolkit/translate-toolkit-2.0.0.ebuild
new file mode 100644
index 000000000000..327a54b47247
--- /dev/null
+++ b/dev-python/translate-toolkit/translate-toolkit-2.0.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MY_PN="${PN/-toolkit}"
+MY_PV="${PV/_beta/b}"
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="https://github.com/translate/translate"
+SRC_URI="https://github.com/${MY_PN}/${MY_PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc +html +ical +ini +subtitles +yaml"
+
+COMMON_DEPEND="
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+"
+DEPEND="${COMMON_DEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+RDEPEND="${COMMON_DEPEND}
+	!dev-python/pydiff
+	app-text/iso-codes
+	>=dev-python/chardet-2.3.0[${PYTHON_USEDEP}]
+	dev-python/diff-match-patch[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.5[${PYTHON_USEDEP}]
+	>=dev-python/python-levenshtein-0.12.0[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( dev-python/iniparse[${PYTHON_USEDEP}] )
+	subtitles? ( $(python_gen_cond_dep 'media-video/gaupol[${PYTHON_USEDEP}]' 'python3*') )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+
+REQUIRED_USE="
+	subtitles? ( || ( $(python_gen_useflags 'python3*') ) )
+"
+
+S="${WORKDIR}/${MY_PN}-${MY_PV}"
+
+python_prepare_all() {
+	# Prevent unwanted d'loading in doc build
+	sed -e "/^    'sphinx.ext.intersphinx',/d" \
+		-e "/html_theme/ s/sphinx-bootstrap/classic/" \
+		-i docs/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( "${S}"/docs/_build/html/. )
+	fi
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	rm -Rf docs || die
+	if ! use html; then
+		rm "${ED%/}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED%/}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED%/}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED%/}"/usr/bin/{sub2po,po2sub} || die
+	fi
+}