dev-ruby/activemodel: add rails 4.2.9

Package-Manager: Portage-2.3.6, Repoman-2.3.1

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-ruby/activemodel/activemodel-4.2.9.ebuild b/dev-ruby/activemodel/activemodel-4.2.9.ebuild
new file mode 100644
index 000000000000..98833b181982
--- /dev/null
+++ b/dev-ruby/activemodel/activemodel-4.2.9.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby21 ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_DOCDIR=""
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"
+
+RUBY_FAKEGEM_GEMSPEC="activemodel.gemspec"
+
+inherit ruby-fakegem versionator
+
+DESCRIPTION="Toolkit for building modeling frameworks like Active Record and Active Resource"
+HOMEPAGE="https://github.com/rails/rails"
+SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="$(get_version_component_range 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~amd64-linux"
+IUSE=""
+
+RUBY_S="rails-${PV}/${PN}"
+
+ruby_add_rdepend "
+	~dev-ruby/activesupport-${PV}:*
+	>=dev-ruby/builder-3.1:* =dev-ruby/builder-3*:*
+"
+
+ruby_add_bdepend "
+	test? (
+		dev-ruby/bundler
+		>=dev-ruby/railties-4.2.0
+		dev-ruby/test-unit:2
+		>=dev-ruby/mocha-0.14.0:0.14
+		>=dev-ruby/bcrypt-ruby-3.1.7
+	)"
+
+all_ruby_prepare() {
+	# Remove items from the common Gemfile that we don't need for this
+	# test run. This also requires handling some gemspecs.
+	sed -i -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|execjs\|jquery-rails\|'mysql'\|journey\|ruby-prof\|stackprof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|debugger\|sprockets-rails\|redcarpet\|uglifier\|minitest\|mime-types\|sprockets\|stackprof\)/ s:^:#:" \
+		-e '/:job/,/end/ s:^:#:' \
+		-e '/group :doc/,/^end/ s:^:#:' ../Gemfile || die
+	rm ../Gemfile.lock || die
+}