dev-ruby/git: add 1.3.0

Package-Manager: portage-2.2.26

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-ruby/git/git-1.3.0.ebuild b/dev-ruby/git/git-1.3.0.ebuild
new file mode 100644
index 000000000000..6dc081c86d74
--- /dev/null
+++ b/dev-ruby/git/git-1.3.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+USE_RUBY="ruby20 ruby21 ruby22 ruby23"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG README.md"
+
+RUBY_FAKEGEM_GEMSPEC="git.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Library for using Git in Ruby"
+HOMEPAGE="https://github.com/schacon/ruby-git"
+SRC_URI="https://github.com/schacon/ruby-git/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+RUBY_S="ruby-git-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+
+DEPEND+="test? ( >=dev-vcs/git-1.6.0.0 app-arch/tar )"
+RDEPEND+=">=dev-vcs/git-1.6.0.0"
+
+ruby_add_bdepend "test? ( dev-ruby/test-unit:2 )"
+
+all_ruby_prepare() {
+	# Needs test-unit, the test-unit version distributed with ruby20 is
+	# not new enough.
+	sed -i -e '3igem "test-unit"' Rakefile || die
+
+	# Don't use hardcoded /tmp directory.
+	sed -i -e "s:/tmp:${TMPDIR}:" tests/units/test_archive.rb tests/test_helper.rb || die
+}