dev-util/bitcoin-tx: Bump to 0.21.0

Signed-off-by: Luke Dashjr <luke-jr+git@utopios.org>
Closes: https://github.com/gentoo/gentoo/pull/19282
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 104 insertions, 0 deletions

diff --git a/dev-util/bitcoin-tx/bitcoin-tx-0.21.0.ebuild b/dev-util/bitcoin-tx/bitcoin-tx-0.21.0.ebuild
new file mode 100644
index 000000000000..626c25324b4f
--- /dev/null
+++ b/dev-util/bitcoin-tx/bitcoin-tx-0.21.0.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools bash-completion-r1
+
+BITCOINCORE_COMMITHASH="95ea54ba089610019a74c1176a2c7c0dba144b1c"
+KNOTS_PV="${PV}.knots20210130"
+KNOTS_P="bitcoin-${KNOTS_PV}"
+
+DESCRIPTION="Command-line Bitcoin transaction tool"
+HOMEPAGE="https://bitcoincore.org/ https://bitcoinknots.org/"
+SRC_URI="
+	https://github.com/bitcoin/bitcoin/archive/${BITCOINCORE_COMMITHASH}.tar.gz -> bitcoin-v${PV}.tar.gz
+	https://bitcoinknots.org/files/0.21.x/${KNOTS_PV}/${KNOTS_P}.patches.txz -> ${KNOTS_P}.patches.tar.xz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="knots"
+
+DEPEND="
+	>=dev-libs/boost-1.58.0:=[threads(+)]
+	>dev-libs/libsecp256k1-0.1_pre20200911:=[recovery,schnorr]
+	>=dev-libs/univalue-1.0.4:=
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	>=sys-devel/autoconf-2.69
+	>=sys-devel/automake-1.13
+"
+
+DOCS=(
+	doc/bips.md
+	doc/release-notes.md
+)
+
+S="${WORKDIR}/bitcoin-${BITCOINCORE_COMMITHASH}"
+
+pkg_pretend() {
+	if use knots; then
+		elog "You are building ${PN} from Bitcoin Knots."
+		elog "For more information, see:"
+		elog "https://bitcoinknots.org/files/0.21.x/${KNOTS_PV}/${KNOTS_P}.desc.html"
+	else
+		elog "You are building ${PN} from Bitcoin Core."
+		elog "For more information, see:"
+		elog "https://bitcoincore.org/en/2021/01/14/release-${PV}/"
+	fi
+}
+
+src_prepare() {
+	local knots_patchdir="${WORKDIR}/${KNOTS_P}.patches/"
+
+	eapply "${knots_patchdir}/${KNOTS_P}.syslibs.patch"
+
+	if use knots; then
+		eapply "${knots_patchdir}/${KNOTS_P}.f.patch"
+		eapply "${knots_patchdir}/${KNOTS_P}.branding.patch"
+		eapply "${knots_patchdir}/${KNOTS_P}.ts.patch"
+	fi
+
+	eapply_user
+
+	echo '#!/bin/true' >share/genbuild.sh || die
+	mkdir -p src/obj || die
+	echo "#define BUILD_SUFFIX gentoo${PVR#${PV}}" >src/obj/build.h || die
+
+	eautoreconf
+	rm -r src/leveldb src/secp256k1 || die
+}
+
+src_configure() {
+	local my_econf=(
+		--disable-asm
+		--without-qtdbus
+		--without-qrencode
+		--without-miniupnpc
+		--disable-tests
+		--disable-wallet
+		--disable-zmq
+		--enable-util-tx
+		--disable-util-cli
+		--disable-util-wallet
+		--disable-bench
+		--without-libs
+		--without-daemon
+		--without-gui
+		--disable-fuzz
+		--disable-ccache
+		--disable-static
+		--with-system-libsecp256k1
+		--with-system-univalue
+	)
+	econf "${my_econf[@]}"
+}
+
+src_install() {
+	default
+
+	newbashcomp contrib/${PN}.bash-completion ${PN}
+}