dev-util/buildbot: Version bump

The test suite (and it's new deps) is fully functional now, passes all tests.

Package-Manager: Portage-2.3.3_p7, Repoman-2.3.1

3 files changed, 250 insertions, 0 deletions

diff --git a/dev-util/buildbot/Manifest b/dev-util/buildbot/Manifest
index 872f70f79c2e..623b6d01cd46 100644
--- a/dev-util/buildbot/Manifest
+++ b/dev-util/buildbot/Manifest
@@ -2,3 +2,5 @@ DIST buildbot-0.8.10.tar.gz 4822307 SHA256 c4964d2ebd81cb80a14cb058fb2aab0572a1d
 DIST buildbot-0.8.12.tar.gz 4834352 SHA256 c6b66976dff712268566574d57131ec15e5682f6d4390cd5c8559bab0980c4d6 SHA512 18c5144132fb033f3581d3c494d5e8ff35d3e8b1548764452ce9ae543d710e58a2c6e3e8e46a0ef237804f9a6a45485890ae4616ab655fb00d4ccf328d6f6645 WHIRLPOOL 5754b7c0278fb5e7da8a7dd66253f6f4d12f54c125f6a78aa9018a2b6b22fd88a27e79e6821ab05e4cd9e87bf0dd08c3c73c7914d4c499ac13c48ca232ed21c8
 DIST buildbot-0.9.0.post1.tar.gz 3013406 SHA256 afd8229c9fd33daa6d8227cd665c75b1b25c47ffcc4046ab5fd5b290ccd536a3 SHA512 0b171ca6ed15b15b4df23d0618cb7d98f6ae922efaa1e35a9458efaaf676b80a6ff3be36231b8ca31cadf89c3968425c560a0bff3630e8792d179462eba0da67 WHIRLPOOL e440826e4a027b42d28c0f3a0afca3c46ec5dc0b4d629fcef75de4b3350cffa2208e0024983f0ffebd1df38a5d860c6bd541fc1c3e28f8b6669ee93a4d4be8b4
 DIST buildbot-0.9.1.tar.gz 3051975 SHA256 a9f385f66f5cc3021f4cbfce92496673ebf9171578fa9e5ae4f66732276d64ce SHA512 c3b845a3607c5eaa0a5076755bc0e285ba7c6809f9d7934fab7c6cf8299610e921034656cf3792113961176a821138c6d069122d4d1f1698f16badf3ef9a0dea WHIRLPOOL 6767878665f09ff7b6219ddcda73487b441f3e33ce580fc2df2f16d430217d4ac38b93e22a3f3abd9c8380ac6e6c93de6767faec1aa5615f82fbe8d8e20759e1
+DIST buildbot-0.9.2.tar.gz 3026977 SHA256 d33ec059941cf830c8f7b7f336a76e32e7122e2690a27b784efeddc6dbf4564a SHA512 a1c6345bcceb5c8f4ed600542625eee81e59af00a1b12054fe77e3b4ed5536b7004fcbd07cfc96baa3061193eb79e4290e056cf7157b71831370654c057a2c57 WHIRLPOOL 075a00d85df5321180345348a02ac12cc8a1bea36d6e60617ebe54de71ce5a989fcf009822834dad1994a6f83ebb5c6132f350902fd31d5b279c5c13014bb4b9
+DIST buildbot-test_templates.tar.xz 304 SHA256 3d581b74c21f88119f7e5f93f381f2004662ca7219aae9a05f0bd3f8cae48317 SHA512 87ba914896d86f70e2e4b24a51248c475bf24fad4c02e3a99d6d7fa41b5a57f369865b20a7c30dafa3162ba50ccb04de1809b0cf9d53e45537738e4821229866 WHIRLPOOL 151dc42ceed8e90c96cdd0b6e937f13019c0d6cd5e2e878ee971cbc69ce4ea56b240b58fa743766bd0d71cafa38279e37be077324eb5ece7b99df46eaf566dfe
diff --git a/dev-util/buildbot/buildbot-0.9.2.ebuild b/dev-util/buildbot/buildbot-0.9.2.ebuild
new file mode 100644
index 000000000000..529c29300973
--- /dev/null
+++ b/dev-util/buildbot/buildbot-0.9.2.ebuild
@@ -0,0 +1,223 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+PYTHON_REQ_USE="sqlite"
+PYTHON_COMPAT=( python2_7 )
+
+EGIT_REPO_URI="https://github.com/buildbot/${PN}.git"
+
+[[ ${PV} == *9999 ]] && inherit git-r3
+inherit readme.gentoo-r1 user systemd distutils-r1
+
+MY_PV="${PV/_p/p}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="BuildBot build automation system"
+HOMEPAGE="http://trac.buildbot.net/ https://github.com/buildbot/buildbot http://pypi.python.org/pypi/buildbot"
+if [[ ${PV} != *9999 ]]; then
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz
+		http://dev.gentoo.org/~dolsen/distfiles/buildbot-test_templates.tar.xz"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+if [[ ${PV} == *9999 ]]; then
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64"
+fi
+
+IUSE="crypt doc examples irc mail manhole test"
+
+RDEPEND=">=dev-python/jinja-2.1[${PYTHON_USEDEP}]
+	|| (
+		>=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+		>=dev-python/twisted-web-14.0.1[${PYTHON_USEDEP}]
+	)
+	>=dev-python/autobahn-0.16.0[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-0.8[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-migrate-0.9[${PYTHON_USEDEP}]
+	crypt? (
+		>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+	)
+	irc? (
+		dev-python/txrequests[${PYTHON_USEDEP}]
+		|| ( >=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+			>=dev-python/twisted-words-14.0.1[${PYTHON_USEDEP}]
+		)
+	)
+	mail? (
+		|| ( >=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+			>=dev-python/twisted-mail-14.0.1[${PYTHON_USEDEP}]
+		)
+	)
+	manhole? (
+		|| ( >=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+			>=dev-python/twisted-conch-14.0.1[${PYTHON_USEDEP}]
+		)
+	)
+	dev-python/future[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
+	>=dev-python/txaio-2.2.2[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	>=dev-python/setuptools-21.2.1[${PYTHON_USEDEP}]
+	doc? ( >=dev-python/sphinx-1.4.3[${PYTHON_USEDEP}] )
+	test? (
+		>=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		=dev-python/httpretty-0.8.10[${PYTHON_USEDEP}]
+		|| (
+			>=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+			(
+				>=dev-python/twisted-mail-14.0.1[${PYTHON_USEDEP}]
+				>=dev-python/twisted-web-14.0.1[${PYTHON_USEDEP}]
+				>=dev-python/twisted-words-14.0.1[${PYTHON_USEDEP}]
+			)
+		)
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/boto3[${PYTHON_USEDEP}]
+		dev-python/ramlfications[${PYTHON_USEDEP}]
+		dev-python/pyjade[${PYTHON_USEDEP}]
+		dev-python/txgithub[${PYTHON_USEDEP}]
+		dev-python/txrequests[${PYTHON_USEDEP}]
+		>=dev-python/treq-16.0.0[${PYTHON_USEDEP}]
+		dev-python/setuptools_trial[${PYTHON_USEDEP}]
+		~dev-util/buildbot-www-${PV}[${PYTHON_USEDEP}]
+	)"
+
+# still yet to be added deps
+# doc? (     'sphinxcontrib-blockdiag',
+#            'sphinxcontrib-spelling',
+#            'pyenchant',
+#            'docutils>=0.8',
+#            'sphinx-jinja',)
+
+S=${WORKDIR}/${MY_P}
+[[ ${PV} == *9999 ]] && S=${S}/master
+
+pkg_setup() {
+	enewuser buildbot
+
+	DOC_CONTENTS="The \"buildbot\" user and the \"buildmaster\" init script has been added
+		to support starting buildbot through Gentoo's init system. To use this,
+		execute \"emerge --config =${CATEGORY}/${PF}\" to create a new instance.
+		The scripts can	run as a different user if desired."
+}
+
+src_unpack() {
+	unpack ${MY_P}.tar.gz
+	cd ${MY_P}/buildbot/test/unit
+	unpack buildbot-test_templates.tar.xz
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/buildbot-0.9.Addmissedtestingtemplates.patch
+	}
+
+src_compile() {
+	distutils-r1_src_compile
+
+	if use doc; then
+		einfo "Generation of documentation"
+		pushd docs > /dev/null
+		#'man' target is currently broken
+		emake html
+		popd > /dev/null
+	fi
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	doman docs/buildbot.1
+
+	if use doc; then
+		dohtml -r docs/_build/html/
+		# TODO: install man pages
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r contrib docs/examples
+	fi
+
+	newconfd "${FILESDIR}/buildmaster.confd" buildmaster
+	newinitd "${FILESDIR}/buildmaster.initd" buildmaster
+	systemd_dounit "${FILESDIR}/buildmaster.target"
+	systemd_newunit "${FILESDIR}/buildmaster_at.service" "buildmaster@.service"
+	systemd_install_serviced "${FILESDIR}/buildmaster_at.service.conf" "buildmaster@.service"
+
+	readme.gentoo_create_doc
+}
+
+python_test() {
+	distutils_install_for_testing
+
+	esetup.py test || die "Tests failed under ${EPYTHON}"
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	if [[ -n ${REPLACING_VERSIONS} ]]; then
+		ewarn
+		ewarn "Starting with buildbot-0.8.12-r2, more than one instance of buildmaster"
+		ewarn "can be run simultaneously. Note that \"BASEDIR\" in the buildbot configuration file"
+		ewarn "is now the common base directory for all instances. If you are migrating from an older"
+		ewarn "version, make sure that you copy the current contents of \"BASEDIR\" to a subdirectory."
+		ewarn "The name of the subdirectory corresponds to the name of the buildmaster instance."
+		ewarn "In order to start the service running OpenRC-based systems need to link to the init file:"
+		ewarn "    ln --symbolic --relative /etc/init.d/buildmaster /etc/init.d/buildmaster.myinstance"
+		ewarn "    rc-update add buildmaster.myinstance default"
+		ewarn "    /etc/init.d/buildmaster.myinstance start"
+		ewarn "Systems using systemd can do the following:"
+		ewarn "    systemctl enable buildmaster@myinstance.service"
+		ewarn "    systemctl enable buildmaster.target"
+		ewarn "    systemctl start buildmaster.target"
+		elog
+		elog "Upstream recommends the following when upgrading:"
+		elog "Each time you install a new version of Buildbot, you should run the"
+		elog "\"buildbot upgrade-master\" command on each of your pre-existing build masters."
+		elog "This will add files and fix (or at least detect) incompatibilities between"
+		elog "your old config and the new code."
+	fi
+	elog
+	elog "In order to create a new instance of buildmaster, execute:"
+	elog "    emerge --config =${CATEGORY}/${PF}"
+}
+
+pkg_config() {
+	local buildmaster_path="/var/lib/buildmaster"
+	einfo "This will prepare a new buildmaster instance in ${buildmaster_path}."
+	einfo "Press Control-C to abort."
+
+	einfo "Enter the name for the new instance: "
+	read instance_name
+	[[ -z "${instance_name}" ]] && die "Invalid instance name"
+
+	local instance_path="${buildmaster_path}/${instance_name}"
+	if [[ -e "${instance_path}" ]]; then
+		eerror "The instance with the specified name already exists:"
+		eerror "${instance_path}"
+		die "Instance already exists"
+	fi
+
+	local buildbot="/usr/bin/buildbot"
+	if [[ ! -d "${buildmaster_path}" ]]; then
+		mkdir --parents "${buildmaster_path}" || die "Unable to create directory ${buildmaster_path}"
+	fi
+	"${buildbot}" create-master "${instance_path}" &>/dev/null || die "Creating instance failed"
+	chown --recursive buildbot "${instance_path}" || die "Setting permissions for instance failed"
+	mv "${instance_path}/master.cfg.sample" "${instance_path}/master.cfg" \
+		|| die "Moving sample configuration failed"
+	ln --symbolic --relative "/etc/init.d/buildmaster" "/etc/init.d/buildmaster.${instance_name}" \
+		|| die "Unable to create link to init file"
+
+	einfo "Successfully created a buildmaster instance at ${instance_path}."
+	einfo "To change the default settings edit the master.cfg file in this directory."
+}
diff --git a/dev-util/buildbot/files/buildbot-0.9.Addmissedtestingtemplates.patch b/dev-util/buildbot/files/buildbot-0.9.Addmissedtestingtemplates.patch
new file mode 100644
index 000000000000..3546c3111ba3
--- /dev/null
+++ b/dev-util/buildbot/files/buildbot-0.9.Addmissedtestingtemplates.patch
@@ -0,0 +1,25 @@
+From 5da64c3dda866a3e3ddf52ad00f455dc2c536a18 Mon Sep 17 00:00:00 2001
+From: Brian Dolbec <dolsen@gentoo.org>
+Date: Wed, 4 Jan 2017 17:44:56 -0800
+Subject: [PATCH] master/setup.py: Add missed testing templates
+
+---
+ master/setup.py | 2 ++
+ 1 file changed, 2 insertions(+)
+
+diff --git a/master/setup.py b/master/setup.py
+index be2ace952..79bcf143f 100755
+--- a/master/setup.py
++++ b/master/setup.py
+@@ -206,6 +206,8 @@ setup_args = {
+         ]),
+         include("buildbot/spec", "*.raml"),
+         include("buildbot/spec/types", "*.raml"),
++        include("buildbot/test/unit/test_templates_dir", "*.html"),
++        include("buildbot/test/unit/test_templates_dir/plugin", "*.*"),
+     ] + include_statics("buildbot/www/static"),
+     'cmdclass': {'install_data': install_data_twisted,
+                  'sdist': our_sdist},
+-- 
+2.11.0
+