proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-util/devhelp/devhelp-3.16.1.ebuild b/dev-util/devhelp/devhelp-3.16.1.ebuild
new file mode 100644
index 000000000000..86d7b3addb9e
--- /dev/null
+++ b/dev-util/devhelp/devhelp-3.16.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+# gedit-3.8 is python3 only, this also per:
+# https://bugzilla.redhat.com/show_bug.cgi?id=979450
+PYTHON_COMPAT=( python{3_3,3_4} )
+
+inherit gnome2 python-single-r1 toolchain-funcs
+
+DESCRIPTION="An API documentation browser for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Devhelp"
+
+LICENSE="GPL-2+"
+SLOT="0/3-1" # subslot = 3-(libdevhelp-3 soname version)
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="gedit"
+REQUIRED_USE="gedit? ( ${PYTHON_REQUIRED_USE} )"
+
+# FIXME: automagic python dependency
+COMMON_DEPEND="
+	>=dev-libs/glib-2.37.3:2
+	>=x11-libs/gtk+-3.13.4:3
+	>=net-libs/webkit-gtk-2:4
+"
+RDEPEND="${COMMON_DEPEND}
+	gedit? (
+		${PYTHON_DEPS}
+		app-editors/gedit[introspection,python,${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		x11-libs/gtk+[introspection] )
+	gnome-base/gsettings-desktop-schemas
+"
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+"
+pkg_setup() {
+	use gedit && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	if ! use gedit ; then
+		sed -e '/SUBDIRS/ s/gedit-plugin//' -i misc/Makefile.{am,in} || die
+	fi
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=""
+	# ICC is crazy, silence warnings (bug #154010)
+	if [[ $(tc-getCC) == "icc" ]] ; then
+		myconf="--with-compile-warnings=no"
+	fi
+	gnome2_src_configure ${myconf}
+}