proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 58 insertions, 0 deletions

diff --git a/dev-util/diffuse/diffuse-0.4.8.ebuild b/dev-util/diffuse/diffuse-0.4.8.ebuild
new file mode 100644
index 000000000000..f1ea525ddd8e
--- /dev/null
+++ b/dev-util/diffuse/diffuse-0.4.8.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit fdo-mime python-single-r1
+
+DESCRIPTION="A graphical tool to compare and merge text files"
+HOMEPAGE="http://diffuse.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86 ~x64-solaris"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	dev-python/pygtk[${PYTHON_USEDEP}]"
+# file collision, bug #279018
+DEPEND="${DEPEND}
+	!sci-chemistry/tinker"
+
+src_prepare() {
+	local i p
+
+	# linguas handling wrt #406433
+	if [[ -n "${LINGUAS+x}" ]] ; then
+		for i in $(for p in translations/*.po ; do echo ${p%.po} ; done) ; do
+			if ! has ${i##*/} ${LINGUAS} ; then
+				rm "${S}"/${i}.po || die
+			fi
+		done
+	fi
+
+	python_fix_shebang src/usr/bin/diffuse
+}
+
+src_install() {
+	"${PYTHON}" install.py \
+		--prefix="${EPREFIX}"/usr \
+		--sysconfdir="${EPREFIX}"/etc \
+		--files-only \
+		--destdir="${D}" \
+		|| die "Installation failed"
+	dodoc AUTHORS ChangeLog README
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}