dev-vcs/fossil: Bump to 2.4, improve metadata

Improve some of the notes in metadata.xml to make it a bit clearer as
to what affect the use flag will have.

split up some of the use flags as one doesn’t necessitate the other
with tcl-stubs.

Package-Manager: Portage-2.3.13, Repoman-2.3.3

1 files changed, 57 insertions, 0 deletions

diff --git a/dev-vcs/fossil/fossil-2.4.ebuild b/dev-vcs/fossil/fossil-2.4.ebuild
new file mode 100644
index 000000000000..234ccb888c9e
--- /dev/null
+++ b/dev-vcs/fossil/fossil-2.4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="Simple, high-reliability, source control management, and more"
+HOMEPAGE="http://www.fossil-scm.org/"
+SRC_URI="http://www.fossil-scm.org/index.html/uv/fossil-src-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="debug fusefs json -legacy-mv-rm -miniz system-sqlite +ssl static
+	  tcl tcl-stubs -tcl-private-stubs th1-docs th1-hooks"
+
+REQUIRED_USE="ssl? ( !miniz )"
+
+DEPEND="
+	sys-libs/zlib
+	|| ( sys-libs/readline:0 dev-libs/libedit )
+	system-sqlite? ( >=dev-db/sqlite-3.20.0:3 )
+	ssl? ( dev-libs/openssl:0 )
+	tcl? ( dev-lang/tcl:0= )
+"
+RDEPEND="${DEPEND}"
+
+# Tests can't be run from the build directory
+RESTRICT="test"
+
+src_configure() {
+	# this is not an autotools situation so don't make it seem like one
+	# --with-tcl: works
+	# --without-tcl: dies
+	local myconf="--with-openssl=$(usex ssl auto none)"
+	use debug         && myconf+=' --fossil-debug'
+	use json          && myconf+=' --json'
+	use system-sqlite && myconf+=' --disable-internal-sqlite'
+	use static        && myconf+=' --static'
+
+	use fusefs || myconf+=' --disable-fusefs'
+
+	local u useflags
+	useflags=( legacy-mv-rm miniz tcl tcl-stubs tcl-private-stubs
+			   th1-docs th1-hooks )
+	for u in ${useflags[@]} ; do
+		use ${u} &&  myconf+=" --with-${u}"
+	done
+
+	tc-export CC
+	./configure ${myconf} || die
+}
+
+src_install() {
+	dobin fossil
+}