proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 87 insertions, 0 deletions

diff --git a/dev-vcs/veracity/veracity-1.0.0.10517.ebuild b/dev-vcs/veracity/veracity-1.0.0.10517.ebuild
new file mode 100644
index 000000000000..f75dac8403e7
--- /dev/null
+++ b/dev-vcs/veracity/veracity-1.0.0.10517.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+inherit eutils cmake-utils
+
+JS_P=js-1.8.0-rc1
+
+DESCRIPTION="A modern and featureful DVCS (distributed version control system)"
+HOMEPAGE="http://veracity-scm.com/"
+SRC_URI="http://download.sourcegear.com/Veracity/release/${PV}/${PN}-source-${PV}.tar.gz
+
+	ftp://ftp.mozilla.org/pub/mozilla.org/js/${JS_P}.tar.gz
+	http://ftp.mozilla.org/pub/mozilla.org/js/${JS_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-linux"
+IUSE="test"
+
+S=${WORKDIR}/${PN}
+
+# Tests fail in 1.0.0.10517.
+RESTRICT=test
+
+# Veracity can only use the API from spidermonkey-1.8.0 which isn't
+# available in gentoo-x86. It seems that spidermonkey needs to be
+# SLOTed... because Veracity needs differing amounts of nontrivial work
+# to support spidermonkey-1.8.2 or any newer spidermonkey.
+#
+# || ( >=dev-lang/spidermonkey-1.8[threadsafe] >=dev-lang/spidermonkey-1.8.5 )
+RDEPEND="
+	dev-libs/icu
+	net-misc/curl
+	dev-libs/nspr
+	sys-apps/util-linux
+	dev-db/sqlite:3
+	sys-libs/zlib"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( app-arch/unzip )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-werror.patch
+	epatch "${FILESDIR}"/${P}-system-sqlite.patch
+	epatch "${FILESDIR}"/${P}-spidermonkey-as-needed.patch
+
+	rm -rf src/thirdparty || die
+
+	pushd "${WORKDIR}"/js || die
+	(
+		EPATCH_OPTS+=" -p8"
+		epatch "${S}"/thirdparty/patches/js-1.8.0-rc1__{jsapi.c,jscntxt.{c,h}}.patch
+	)
+}
+
+src_configure() {
+	# Convince cmake scripts that spidermonkey has been prepared.
+	mkdir -p thirdparty/{include/spidermonkey,lib} || die
+
+	local mycmakeargs=(
+		-DVVTHIRDPARTY="${S}"/thirdparty
+		-DSPIDERMONKEY_INCDIR="${S}"/thirdparty/include
+		-DSPIDERMONKEY_LIB="${S}"/thirdparty/lib/libjs.a
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	einfo "Compiling embedded spidermonkey (${JS_P})."
+	# Based on thirdparty/build_linux.sh.
+	emake -j1 \
+		-C "${WORKDIR}"/js/src \
+		JS_DIST="${EPREFIX}"/usr \
+		JS_THREADSAFE=1 \
+		BUILD_OPT=1 \
+		-f Makefile.ref
+	cp "${WORKDIR}"/js/src/{*.{h,msg,tbl},Linux_All_OPT.OBJ/*.h} thirdparty/include/spidermonkey/ \
+		|| die "Preparing embedded spidermonkey."
+	cp "${WORKDIR}"/js/src/Linux_All_OPT.OBJ/libjs.a thirdparty/lib/ \
+		|| die "Preparing embedded spidermonkey."
+
+	einfo "Compiling ${P}."
+	cmake-utils_src_compile
+}