proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 78 insertions, 0 deletions

diff --git a/games-action/chromium-bsu/chromium-bsu-0.9.15.1.ebuild b/games-action/chromium-bsu/chromium-bsu-0.9.15.1.ebuild
new file mode 100644
index 000000000000..80b6eba68b1f
--- /dev/null
+++ b/games-action/chromium-bsu/chromium-bsu-0.9.15.1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils gnome2-utils games
+
+DESCRIPTION="Chromium B.S.U. - an arcade game"
+HOMEPAGE="http://chromium-bsu.sourceforge.net/"
+SRC_URI="mirror://sourceforge/chromium-bsu/${P}.tar.gz"
+
+LICENSE="Clarified-Artistic"
+SLOT="0"
+KEYWORDS="amd64 ppc x86"
+IUSE="mixer nls +sdl"
+
+RDEPEND="media-fonts/dejavu
+	media-libs/quesoglc
+	media-libs/glpng
+	virtual/opengl
+	virtual/glu
+	x11-libs/libXmu
+	mixer? ( media-libs/sdl-mixer )
+	!mixer? (
+		media-libs/freealut
+		media-libs/openal
+	)
+	nls? ( virtual/libintl )
+	sdl? (
+		media-libs/libsdl[X]
+		media-libs/sdl-image[png]
+	)
+	!sdl? ( media-libs/freeglut )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+src_configure() {
+	egamesconf \
+		--disable-ftgl \
+		--enable-glc \
+		$(use_enable mixer sdlmixer) \
+		$(use_enable !mixer openal) \
+		$(use_enable nls) \
+		$(use_enable sdl) \
+		$(use_enable sdl sdlimage) \
+		$(use_enable !sdl glut)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	# remove installed /usr/games/share stuff
+	rm -rf "${D}"/"${GAMES_PREFIX}"/share/
+
+	newicon -s 64 misc/${PN}.png ${PN}.png
+	domenu misc/chromium-bsu.desktop
+
+	# install documentation
+	dodoc AUTHORS README NEWS
+	dohtml "${S}"/data/doc/*.htm
+	dohtml -r "${S}"/data/doc/images
+
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}