proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 58 insertions, 0 deletions

diff --git a/games-arcade/wop/wop-0.4.3-r1.ebuild b/games-arcade/wop/wop-0.4.3-r1.ebuild
new file mode 100644
index 000000000000..c8edd635a714
--- /dev/null
+++ b/games-arcade/wop/wop-0.4.3-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+EAPI=5
+inherit eutils toolchain-funcs games
+
+MY_DATA_V="2005-12-21"
+MY_DATA_P="${PN}data-${MY_DATA_V}"
+DESCRIPTION="Worms of Prey - A multi-player, real-time clone of Worms"
+HOMEPAGE="http://wormsofprey.org/"
+SRC_URI="http://wormsofprey.org/download/${P}-src.tar.bz2
+	http://wormsofprey.org/download/${MY_DATA_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86 ~x86-fbsd"
+IUSE=""
+
+RDEPEND="media-libs/libsdl
+	media-libs/sdl-net
+	media-libs/sdl-image
+	media-libs/sdl-mixer
+	media-libs/sdl-ttf"
+DEPEND="${RDEPEND}
+	x11-misc/makedepend"
+
+MY_DATA_S=${WORKDIR}/${MY_DATA_P}
+
+src_prepare() {
+	# correct path to global woprc
+	sed -i \
+		-e "s:/etc/woprc:${GAMES_SYSCONFDIR}/woprc:g" \
+		src/wopsettings.cpp \
+		|| die "sed failed"
+	# patch global woprc with the correct data files location and install it
+	sed -i \
+		-e "s:^data =.*$:data = ${GAMES_DATADIR}/${PN}:" \
+		woprc \
+		|| die "sed failed"
+	epatch "${FILESDIR}"/${P}-Makefile.patch \
+		"${FILESDIR}"/${P}-gcc43.patch
+}
+
+src_compile() {
+	emake CXX=$(tc-getCXX)
+}
+
+src_install() {
+	dogamesbin bin/${PN}
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins -r "${MY_DATA_S}"/*
+	insinto "${GAMES_SYSCONFDIR}"
+	doins woprc
+	newicon "${MY_DATA_S}"/images/misc/icons/wop16.png ${PN}.png
+	make_desktop_entry wop "Worms of Prey"
+	dodoc AUTHORS ChangeLog README{,-Libraries.txt} REVIEWS
+	prepgamesdirs
+}